(已解决) 撒手不管版911 的安装程序 P处理

xsllei

... 原911的安装程序 瑞星要误报（BS下）...   论坛里搜了一下..发现有很多.. 大致的测试几个 就不能用...

谁有收藏 可否共享下..



   小弟在此谢过....

[ 本帖最后由 xsllei 于 2008-5-1 06:33 PM 编辑 ]

secowu

转一个给你

1. 
   
2. @Echo Off
   
3. COLOR 2F
   
4. SET TP=%~dp0
   
5. SET TP=%TP:~0,-1%
   
6. Set Prog=        WinPE 专用安装工具     
   
7. Set L1=　　　　　　╭══════════════════╮
   
8. Set L2=　　　　　　║　　　　　　　　　　　　　　　　　　║
   
9. Set L3=　　　╭══┤　%Prog%　 ├══╮
   
10. Set L4=　　　║　　║　　　　　　　　　　　　　　　　　　║　　║
    
11. Set L5=　　　║　　╰══════════════════╯　　║
    
12. Set L6=　　　║　　　　　　　　　　　　　　　　　　　　　　　　║
    
13. Set L7=　　　╟════════════════════════╢
    
14. Set L8=　　　║　                                            　║
    
15. Set L9=　　　╰────────────────────────╯
    
16. Title %Prog%
    
17. 
    
18. FOR /F "delims=" %%I in (%0) do Set CP=%%~dpI
    
19. Set DOSIMG=MiniPE\Dos.img
    
20. Set SetupINIFile=PESetup.INI
    
21. Set PEFile=MiniPE\WinPE.IS_
    
22. Set PEIni=MiniPE\WinPE.INI
    
23. Set LogFile=PEInstall.log
    
24. If Not Exist .\PESETUP.INI Goto Err0
    
25. For /F "tokens=2 delims=^=" %%I In ('FIND /I ^"外置程序包^" .\%SetupINIFile%') DO Set OPFile=MiniPE\%%I
    
26. 
    
27. Set AddATTR=ATTRIB +S +H +R
    
28. Set DelATTR=ATTRIB -S -H -R
    
29. 
    
30. :Start
    
31. CLS
    
32. Title %Prog%——安装
    
33. Echo.
    
34. Echo %L1%
    
35. Echo %L2%
    
36. Echo %L3%
    
37. Echo %L4%
    
38. Echo %L5%
    
39. Echo %L6%
    
40. Echo 　　　║ 　请选择安装方式：　　　　　　　　　　　　　　 ║
    
41. Echo %L6%
    
42. Echo 　　　║　　[1] 普通安装/启动 (硬盘安装)　　　　　　　　║
    
43. Echo 　　　║　　[2] Grub安装/启动 (硬盘安装，支持 MD5 密码) ║
    
44. Echo 　　　║　　[3] Aero安装/启动 (硬盘安装，支持密码)　　　║
    
45. Echo 　　　║　　[4] Grub安装/启动 (U 盘、移动硬盘安装)　　　║
    
46. Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
    
47. Echo %L6%
    
48. Echo %L7%
    
49. Echo 　　　║　注意: Aero 安装项只适合系统分区在(HD0,0)分区　║
    
50. Echo %L7%
    
51. Echo %L8%
    
52. Echo %L9%
    
53. Echo.
    
54. Set Choice=
    
55. Set /P Choice=　　　请选择要进行的操作 (1/2/3/4/Q) ，然后按回车：
    
56. If "%Choice%"=="" Goto Start
    
57. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
    
58. If /I "%Choice%"=="1" Goto HD
    
59. If /I "%Choice%"=="2" Goto HD
    
60. If /I "%Choice%"=="3" Goto HD
    
61. If /I "%Choice%"=="4" Goto UD
    
62. If /I "%Choice%"=="Q" Exit
    
63. Goto Start
    
64. 
    
65. :HD
    
66. Set RP=
    
67. For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BOOT.INI Set RP=%%I:
    
68. If "%RP%"=="" Goto HDRPErr
    
69. Set PEDIR=%RP%\MiniPE&&Set TargetP=硬盘&&Set TxtSp=
    
70. If Exist %PEDIR% Goto Err1
    
71. FIND /I "C:\MAOTAO" %RP%\BOOT.INI>NUL 2>NUL
    
72. If "%Errorlevel%"=="0" Goto Err1
    
73. FIND /I "C:\MiniPE" %RP%\BOOT.INI>NUL 2>NUL
    
74. If "%Errorlevel%"=="0" Goto Err1
    
75. bootcfg /timeout 0 >NUL 2>NUL
    
76. If /I "%Choice%"=="1" Goto Install
    
77. If /I "%Choice%"=="2" Goto GInstall
    
78. If /I "%Choice%"=="3" Goto AInstall
    
79. Goto HD
    
80. 
    
81. :UD
    
82. CLS
    
83. Title %Prog%——U 盘安装
    
84. For /F "skip=2 tokens=*" %%I In ('MYINS\CHECKUSB.EXE') DO SET Us=%%I
    
85. If "%Us%"=="当前可移动磁盘分区：" Goto NoUD
    
86. Echo %Us%&&Echo.
    
87. If "%NoUD%"=="Yes" Echo 错误：您设定的分区 %RP% 不存在、写保护、未格式化或不是 U 盘分区，请按任意键重新设定。&&Echo.
    
88. Set /P RP=请选择您的 U 盘盘符（不需要冒号，例如 F）：
    
89. Echo.&&Echo.
    
90. If "%RP%"=="" Goto UD
    
91. If Not "%RP%"=="" Set RP=%RP:~0,1%:
    
92. For /F %%I In ('MYINS\CHECKUSB.EXE %RP%') DO SET Err2=%%I
    
93. If Not "%Err2%"=="1" Set NoUD=Yes&&Goto UD
    
94. Set TestFile=%RP%\MiniPETest_%RANDOM%.MT
    
95. Cd.>%TestFile%
    
96. If Not Exist %TestFile% Set NoUD=Yes&&Goto UD
    
97. FOR /F "delims=" %%I in (%0) do Set TP=%%~dI
    
98. Del %TestFile% /Q>NUL 2>NUL
    
99. for %%i in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do call set rp=%%rp:%%i=%%i%%
    
100. If Not "%RP%"=="" Set RP=%RP:~0,1%:
     
101. if "%TP%"=="%RP%" goto DBU
     
102. Set U=U&&Set PEDIR=%RP%\MiniPE&&Set TargetP= U 盘&&Set TxtSp=
     
103. If Exist %RP%\MAOTAO Goto Err1
     
104. If Exist %PEDIR% Goto Err1
     
105. CLS
     
106. Echo 您选择的 U 盘分区为 %RP%，下面将对您的 U 盘进行格式化并写入引导
     
107. Echo.
     
108. Echo 请严格按照相关工具软件界面中的提示操作，以防出错。请按任意键开始。。。
     
109. PAUSE>NUL
     
110. Start /Wait MYINS\HPUSBFW.EXE
     
111. Start /Wait MYINS\GRUBGUI.EXE
     
112. cls
     
113. echo 请稍候,正在安装中......
     
114. Echo.
     
115. md %rp%\SETUP\MYINS  >NUL 2>NUL
     
116. md %rp%\MINIPE       >NUL 2>NUL
     
117. md %rp%\SETUP\TOOLS  >NUL 2>NUL
     
118. copy myins\aero.sys %rp%\setup\myins     >NUL 2>NUL
     
119. copy myins\checkusb.exe %rp%\setup\myins >NUL 2>NUL
     
120. copy myins\grubgui.exe %rp%\setup\myins  >NUL 2>NUL
     
121. copy myins\grubinst.exe %rp%\setup\myins >NUL 2>NUL
     
122. copy myins\hpusbfw.exe %rp%\setup\myins  >NUL 2>NUL
     
123. copy myins\md5.exe %rp%\setup\myins      >NUL 2>NUL
     
124. copy myins\myins.dll %rp%\setup\myins    >NUL 2>NUL
     
125. copy myins\myins.exe %rp%\setup\myins    >NUL 2>NUL
     
126. copy myins\ntboot.exe %rp%\setup\myins   >NUL 2>NUL
     
127. copy pesetup.ini %rp%\setup              >NUL 2>NUL
     
128. copy pesetup.cmd %rp%\setup              >NUL 2>NUL
     
129. copy tools\BMP2COVE.exe %rp%\setup\tools >NUL 2>NUL
     
130. copy tools\WIMTOOL.EXE %rp%\setup\tools  >NUL 2>NUL
     
131. copy tools\MD5CRYPT.rar %rp%\setup\tools >NUL 2>NUL
     
132. 
     
133. copy tools\WimFltr.exe %rp%\setup\tools    >NUL 2>NUL
     
134. copy tools\WimShExt.DLL %rp%\setup\tools    >NUL 2>NUL
     
135. copy tools\WimCMD.exe %rp%\setup\tools    >NUL 2>NUL
     
136. copy tools\WimICON.exe %rp%\setup\tools    >NUL 2>NUL
     
137. copy tools\GrubMenu.exe %rp%\setup\tools    >NUL 2>NUL
     
138. 
     
139. cls
     
140. echo.
     
141. Echo 您的 U 盘已经成功格式化并写入了 Grub 引导，请按任意键继续......
     
142. PAUSE>NUL
     
143. Goto GInstall
     
144. 
     
145. :DBU
     
146. echo ------------------------------------------------------------------
     
147. ECHO 您选择的安装盘符与目标盘符重复，不需要再安装。请选择其它的安装方式
     
148. echo ------------------------------------------------------------------
     
149. pause
     
150. goto start
     
151. 
     
152. :NoUD
     
153. CLS
     
154. Title %Prog%——U 盘安装
     
155. Echo.
     
156. Echo %L1%
     
157. Echo %L2%
     
158. Echo %L3%
     
159. Echo %L4%
     
160. Echo %L5%
     
161. Echo %L6%
     
162. Echo 　　　║ 您的计算机似乎没有安装 U 盘，您想怎么办？　　　║
     
163. Echo %L6%
     
164. Echo 　　　║　　[B] 返回首页，重新选择安装选项。　　　　　　║
     
165. Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
     
166. Echo %L6%
     
167. Echo %L7%
     
168. Echo %L8%
     
169. Echo %L9%
     
170. Echo.
     
171. Set Choice=
     
172. Set /P Choice=　　　请选择要进行的操作 (B/Q) ，然后按回车：
     
173. If "%Choice%"=="" Goto NoUD
     
174. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
     
175. If /I "%Choice%"=="B" Goto Start
     
176. If /I "%Choice%"=="Q" Exit
     
177. Goto NoUD
     
178. Exit
     
179. 
     
180. :Err0
     
181. Echo 错误：安装配置文件丢失！&&Echo.
     
182. Echo 请确认安装配置文件 %SetupINIFile% 存在或到本程序所在目录执行安装。&&Echo.
     
183. Echo 请按任意键退出安装程序。。。
     
184. PAUSE>NUL
     
185. Exit
     
186. 
     
187. :Err1
     
188. CLS
     
189. Title %Prog%——卸载
     
190. Echo.
     
191. Echo %L1%
     
192. Echo %L2%
     
193. Echo %L3%
     
194. Echo %L4%
     
195. Echo %L5%
     
196. Echo %L6%
     
197. Echo 　　　║ 您的%TargetP%中好像已经安装了 WinPE，您想怎么办？%TxtSp%　║
     
198. Echo %L6%
     
199. Echo 　　　║　　[1] 卸载原有的 WinPE，并且重新安装。　　　　║
     
200. Echo 　　　║　　[2] 卸载原有的 WinPE，并且不再安装。　　　　║
     
201. Echo 　　　║　　[B] 返回首页，重新选择安装选项。　　　　　　║
     
202. Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
     
203. Echo %L6%
     
204. Echo %L7%
     
205. Echo %L8%
     
206. Echo %L9%
     
207. Echo.
     
208. Set Choice=
     
209. Set /P Choice=　　　请选择要进行的操作 (1/2/B/Q) ，然后按回车：
     
210. If "%TargetP%"=="硬盘" Set U=
     
211. If "%Choice%"=="" Goto Err1
     
212. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
     
213. If /I "%Choice%"=="1" Set Choi=1&&Goto UnInstall
     
214. If /I "%Choice%"=="2" Goto UnInstall
     
215. If /I "%Choice%"=="B" Goto Start
     
216. If /I "%Choice%"=="Q" Exit
     
217. Goto Err1
     
218. Exit
     
219. 
     
220. :UnInstall
     
221. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE&&Del %RP%\LDRXPE /Q>NUL 2>NUL
     
222. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE&&Del %RP%\WINNT.XPE /Q>NUL 2>NUL
     
223. If Exist %RP%\MTLDR.PE %DelATTR% %RP%\MTLDR.PE&&Del %RP%\MTLDR.PE /Q>NUL 2>NUL
     
224. If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR&&Del %RP%\MTLDR /Q>NUL 2>NUL
     
225. If Exist %RP%\%LogFile% For /F "eol=; tokens=2 delims=^=" %%i In ('find /I ^"WinPE外挂位置^" %RP%\%LogFile%') do SET OPD=%%i
     
226. If Not "%U%"=="" Set OPD=%RP%
     
227. If Exist %OPD%\外置程序 RD %OPD%\外置程序 /S /Q>NUL 2>NUL
     
228. If Exist %RP%\%LogFile% %DelATTR% %RP%\%LogFile%&&Del %RP%\%LogFile% /Q>NUL 2>NUL
     
229. If Exist %RP%\MAOTAO RD %RP%\MAOTAO /S /Q>NUL 2>NUL
     
230. If Exist %RP%\MiniPE RD %RP%\MiniPE /S /Q>NUL 2>NUL
     
231. %DelATTR% %RP%\BOOT.INI>NUL 2>NUL
     
232. Set TMPINIFile=BOOT_%RANDOM%.INI
     
233. If Exist %RP%\BOOT.BAK (
     
234. %DelATTR% %RP%\BOOT.BAK
     
235. TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MAOTAO">%RP%\%TMPINIFile%
     
236. TYPE %RP%\%TMPINIFile%|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI
     
237. ) Else (
     
238. If Exist %RP%\BOOT.INI TYPE %RP%\BOOT.INI|FIND /I /V "C:\MAOTAO">%RP%\%TMPINIFile%
     
239. If Exist %RP%\%TMPINIFile% TYPE %RP%\%TMPINIFile%|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI
     
240. )
     
241. If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK&&Del %RP%\BOOT.BAK>NUL 2>NUL
     
242. If Exist %RP%\%TMPINIFile% %DelATTR% %RP%\%TMPINIFile%&&Del %RP%\%TMPINIFile%>NUL 2>NUL
     
243. If Exist %RP%\BOOT.INI %AddATTR% %RP%\BOOT.INI
     
244. Set RP=
     
245. Title %Prog%——卸载完成
     
246. If "%Choi%"=="1" (Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键准备安装 。。。&&PAUSE>NUL 2>NUL&&Goto Start)
     
247. Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键退出 。。。
     
248. PAUSE>NUL 2>NUL
     
249. Exit
     
250. 
     
251. :Install
     
252. Title %Prog%——普通安装
     
253. If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
     
254. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
     
255. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
     
256. Echo.&&Echo　　　　正在复制文件，请稍候 。。。
     
257. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% MAOTAO.BIN -r -y>NUL 2>NUL
     
258. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y>NUL 2>NUL
     
259. Call :CopyAndSetFiles
     
260. Goto SUCCESS
     
261. 
     
262. :GInstall
     
263. If "%U%"=="" Title %Prog%——Grub安装
     
264. CLS
     
265. Set LDRP=MiniPE\
     
266. Echo 请输入您要设定的密码
     
267. Echo 注意：密码中不许有空格、""、引号等特殊字符
     
268. Echo.
     
269. Set /P Pass1=请输入：
     
270. If "%Pass1%"=="" Goto GInstall
     
271. Echo.&&Echo.
     
272. Echo 请再一次输入您的密码
     
273. Echo.
     
274. Set /P Pass2=请再次输入：
     
275. If "%Pass2%"=="" Goto GInstall
     
276. If Not "%Pass2%"=="%Pass1%" Echo.&&Echo 您两次输入的密码不一致，请重新输入&&Echo 请按任意键重新开始设置密码&&PAUSE>NUL 2>NUL&&Goto GInstall
     
277. If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
     
278. >%PEDIR%\MD5P.TMP <nul Set/p=%Pass2%
     
279. MYINS\MD5.EXE %PEDIR%\MD5P.TMP %PEDIR%\MD5R.TXT>NUL 2>NUL
     
280. For /f %%i In ('type %PEDIR%\md5r.txt') do SET MD5Pass=password --md5 %%i
     
281. MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% MTLDR -r -y>NUL 2>NUL
     
282. >>%RP%\MTLDR Echo %MD5Pass%
     
283. >>%RP%\MTLDR Echo fontfile /minipe/muifont.gz
     
284. >>%RP%\MTLDR Echo splashimage /minipe/bj2008.xpm.gz
     
285. >>%RP%\MTLDR Echo.
     
286. >>%RP%\MTLDR Echo title WinPE 迷你维护系统
     
287. >>%RP%\MTLDR Echo %MD5Pass%
     
288. >>%RP%\MTLDR Echo chainloader /minipe/ldrxpe
     
289. >>%RP%\MTLDR Echo.
     
290. >>%RP%\MTLDR Echo title Grub 命令行
     
291. >>%RP%\MTLDR Echo %MD5Pass%
     
292. >>%RP%\MTLDR Echo commandline
     
293. >>%RP%\MTLDR Echo.
     
294. >>%RP%\MTLDR Echo title DOS 工具箱
     
295. >>%RP%\MTLDR Echo map --mem /minipe/DOS.IMG (fd0)
     
296. >>%RP%\MTLDR Echo map --hook
     
297. >>%RP%\MTLDR Echo chainloader (fd0)+1
     
298. >>%RP%\MTLDR Echo rootnoverify (fd0)
     
299. >>%RP%\MTLDR Echo map --floppies=1
     
300. >>%RP%\MTLDR Echo boot
     
301. >>%RP%\MTLDR Echo.
     
302. >>%RP%\MTLDR Echo title 从第一硬盘第一分区启动
     
303. >>%RP%\MTLDR Echo root ^(hd0,0^)
     
304. >>%RP%\MTLDR Echo chainloader +1
     
305. >>%RP%\MTLDR Echo.
     
306. >>%RP%\MTLDR Echo title 从第二硬盘第一分区启动
     
307. >>%RP%\MTLDR Echo root ^(hd1,0^)
     
308. >>%RP%\MTLDR Echo chainloader ^(hd1,0^)+1
     
309. >>%RP%\MTLDR Echo.
     
310. >>%RP%\MTLDR Echo title 重新启动计算机
     
311. >>%RP%\MTLDR Echo reboot
     
312. >>%RP%\MTLDR Echo.
     
313. >>%RP%\MTLDR Echo title 关闭计算机
     
314. >>%RP%\MTLDR <nul Set/p=halt
     
315. Del %PEDIR%\MD5?.* /Q>NUL 2>NUL
     
316. cls
     
317. Echo.
     
318. Echo 密码设置完成，请牢记您的密码，并按任意键继续 。。。
     
319. PAUSE>NUL 2>NUL
     
320. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
     
321. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
     
322. If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR  
     
323. Echo.
     
324. Echo 正在复制文件，请稍候 。。。
     
325. 
     
326. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% BJ2008.XPM.GZ -r -y >NUL 2>NUL
     
327. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% muifont.gz -r -y    >NUL 2>NUL
     
328. If "%U%"=="" MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR%\ maotaog.bin -r -y   >NUL 2>NUL
     
329. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y  >NUL 2>NUL
     
330. If "%U%"=="" Ren %PEDIR%\maotaog.bin maotao.bin  >NUL 2>NUL
     
331. Call :CopyAndSetFiles
     
332. Goto SUCCESS
     
333. 
     
334. :AInstall
     
335. Title %Prog%——Aero安装
     
336. CLS
     
337. Echo 请输入您要设定的密码
     
338. Echo 注意：密码中不许有空格、""、引号等特殊字符
     
339. Echo.
     
340. Set /P Pass1=请输入：
     
341. If "%Pass1%"=="" Goto AInstall
     
342. Echo.&&Echo.
     
343. Echo 请再一次输入您的密码
     
344. Echo.
     
345. Set /P Pass2=请再次输入：
     
346. If "%Pass2%"=="" Goto AInstall
     
347. If Not "%Pass2%"=="%Pass1%" Echo.&&Echo 您两次输入的密码不一致，请重新输入&&Echo 请按任意键重新开始设置密码&&PAUSE>NUL 2>NUL&&Goto AInstall
     
348. If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
     
349. For /f %%i In (MyIns\Aero.sys) Do MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% %%i -r -y>NUL 2>NUL
     
350. Ren %PEDIR%\maotao.bin avldr.xpe
     
351. Ren %PEDIR%\maotaoa.bin maotao.bin
     
352. >%PEDIR%\airL.gz <nul Set/p=%Pass2%
     
353. Copy /B %PEDIR%\airT.gz+%PEDIR%\airL.gz+%PEDIR%\airW.gz %PEDIR%\airmenu.ini>NUL 2>NUL&&Del %PEDIR%\air?.gz /Q>NUL 2>NUL>NUL 2>NUL
     
354. MyIns\MyIns.exe a -tGZip %PEDIR%\airmenu.gz %PEDIR%\airmenu.ini -w%PEDIR%>NUL 2>NUL&&Del %PEDIR%\airmenu.ini /Q>NUL 2>NUL&&Ren %PEDIR%\airmenu.gz airmenu.ini>NUL 2>NUL
     
355. cls
     
356. Echo.
     
357. Echo 密码设置完成，请牢记您的密码，并按任意键继续 。。。
     
358. PAUSE>NUL 2>NUL
     
359. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
     
360. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
     
361. Echo.
     
362. Echo 正在复制文件，请稍候 。。。
     
363. MOVE %PEDIR%\MTLDR.PE %RP%\>NUL 2>NUL
     
364. Call :CopyAndSetFiles
     
365. Goto SUCCESS
     
366. 
     
367. :HDRPErr
     
368. CLS
     
369. Set RP=
     
370. For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BootMGR Set RP=%%I:&&Set PEDIR=%%I:\MiniPE
     
371. If Not "%RP%"=="" (
     
372.         TITLE %Prog%——检测到 Windows Vista 分区
     
373.         Set OPT=Vista&&Set OPT0=存在 WinVista 分区&&Set OPT1=[I] 将 WimPE 安装到 Windows Vista 分区。
     
374. ) Else (
     
375.         TITLE %Prog%——没有检测到系统分区
     
376.         Set OPT=NewHD&&Set OPT0=没有安装过操作系统&&Set OPT1=[I] 全新硬盘，将 WimPE 安装到活动分区。
     
377. )
     
378. Echo.
     
379. Echo %L1%
     
380. Echo %L2%
     
381. Echo %L3%
     
382. Echo %L4%
     
383. Echo %L5%
     
384. Echo %L6%
     
385. Echo 　　　║　好像您的机器中%OPT0%，您想怎么办？║
     
386. Echo %L6%
     
387. Echo 　　　║　　%OPT1%　　║
     
388. Echo 　　　║　　[B] 返回首页，重新选择安装选项。　　　　　　║
     
389. Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
     
390. Echo %L6%
     
391. Echo 　　　║　注意: 为确保安全，此安装选项可能会卸载不干净！║
     
392. Echo %L7%
     
393. Echo %L8%
     
394. Echo %L9%
     
395. Echo.
     
396. Set Choice=
     
397. Set /P Choice=　　　请选择要进行的操作 (I/B/Q) ，然后按回车：
     
398. If "%Choice%"=="" Goto HDRPErr
     
399. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
     
400. If /I "%Choice%"=="I" If "%OPT%"=="Vista" Goto Vista
     
401. If /I "%Choice%"=="I" If "%OPT%"=="NewHD" Goto NewHD
     
402. If /I "%Choice%"=="B" Goto Start
     
403. If /I "%Choice%"=="Q" Exit
     
404. Goto HDRPErr
     
405. Exit
     
406. 
     
407. :Vista
     
408. Set PEDIR=%RP%\MiniPE
     
409. If Exist %RP%\MAOTAO Goto Err1
     
410. If Exist %PEDIR% Goto Err1
     
411. Echo.&&Echo.
     
412. SET BAKPATH=%SYSTEMDRIVE%\BOOT\BCDBAK.BAK
     
413. SET INFO=WinPe 工具箱
     
414. SET MBRP=\maotaog.bin
     
415. color 2f
     
416. IF NOT EXIST "%systemdrive%\boot\BCD" goto start
     
417. cd /d "%TP%"
     
418. 
     
419. :Vinstall
     
420. cls
     
421. if NOT EXIST %systemroot%\system32\bcdedit.exe goto bcdedit_er
     
422. bcdedit.exe /enum all | find "%MBRP%" && goto installed
     
423. IF NOT EXIST "%BAKPATH%" start /wait bcdedit.exe /export "%BAKPATH%"
     
424. for /f "tokens=2 delims={}" %%i in ('bcdedit.exe /create /d "%INFO%" /application bootsector') do SET CLASSID=%%i
     
425. IF "%CLASSID%"=="" GOTO createerr
     
426. SET CLASSID={%CLASSID%}
     
427. ECHO %CLASSID%>%SYSTEMDRIVE%\BOOT\CLASSID_BK.INI
     
428. bcdedit.exe /set %CLASSID% device boot >nul
     
429. bcdedit.exe /set %CLASSID% path %MBRP% >nul
     
430. bcdedit.exe /displayorder %CLASSID% /addlast >nul
     
431. bcdedit.exe /timeout 3 >nul
     
432. MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% maotaog.bin -r -y>NUL 2>NUL
     
433. MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% MTLDR -r -y>NUL 2>NUL
     
434. attrib %RP%\maotaog.bin +s +h
     
435. attrib %RP%\MTLDR +s +h
     
436. cls
     
437. echo                  安装PE引导环境到Windows Vista
     
438. echo.                  
     
439. echo    ===========================================================
     
440. echo   请选择安装方式：
     
441. Echo 　　　║　　[1] 普通安装/启动 (硬盘安装)　　　　　　　　║
     
442. Echo 　　　║　　[2] Grub安装/启动 (硬盘安装，支持 MD5 密码) ║
     
443. Echo 　　　║　　[3] Aero安装/启动 (硬盘安装，支持密码)　　　║
     
444. Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
     
445. Echo 　　　║　注意: Aero 安装项只适合系统分区在(HD0,0)分区　║
     
446. echo    ===========================================================
     
447. Echo.
     
448. Set Choice=
     
449. Set /P Choice=　　　请选择要进行的操作 (2/3/Q) ，然后按回车：
     
450. If "%Choice%"=="" Goto Start
     
451. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
     
452. If /I "%Choice%"=="1" Goto Install
     
453. If /I "%Choice%"=="2" Goto GInstall
     
454. If /I "%Choice%"=="3" Goto AInstall
     
455. If /I "%Choice%"=="Q" Exit
     
456. pause>nul 2>nul
     
457. 
     
458. :installed
     
459. cls
     
460. echo    本机已经安装过PE，请先卸载！按任意键进行卸载,关闭退出
     
461. pause>nul
     
462. for /f %%i in (%SYSTEMDRIVE%\BOOT\CLASSID_BK.INI) do set CID=%%i
     
463. bcdedit /delete %CID%
     
464. goto Vinstall
     
465. 
     
466. :createerr
     
467. echo.
     
468. echo    创建BCD项错误，安装无法继续！
     
469. echo    按任意键退出。。。。。。
     
470. echo.
     
471. pause>nul
     
472. goto Xend
     
473. 
     
474. :bcdedit_er
     
475. echo.
     
476. echo    非完整Vista系统，安装无法继续！
     
477. echo    按任意键退出。。。。。。
     
478. echo.
     
479. pause>nul
     
480. goto Xend
     
481. 
     
482. :Xend
     
483. echo on
     
484. exit
     
485. 
     
486. :NewHD
     
487. CLS
     
488. TITLE %Prog%——在全新硬盘中安装
     
489. If "%NoNewErr%"=="Yes" Echo 错误：您设定的分区 %RP% 不存在、写保护、或未格式化，请按任意键重新设定。&&Echo.
     
490. Echo 请设置您需要安装 WinPE 到哪个分区（注意一定要是活动分区）
     
491. Echo.
     
492. Set /P RP=请输入您需要安装 WinPE 的分区符（不需要冒号，例如 C），然后按回车：
     
493. Echo.&&Echo.
     
494. If "%RP%"=="" Goto NewHD
     
495. If Not "%RP%"=="" Set RP=%RP:~0,1%:
     
496. For /F %%I In ('MYINS\CHECKUSB.EXE %RP%') DO SET Err2=%%I
     
497. If Not Exist %RP% Set NoNewErr=Yes&&Goto NewHD
     
498. Set TestFile=%RP%\MiniPETest_%RANDOM%.MT
     
499. Cd.>%TestFile%
     
500. If Not Exist %TestFile% Set NoNewErr=Yes&&Goto NewHD
     
501. Del %TestFile% /Q>NUL 2>NUL
     
502. Set PEDIR=%RP%\MiniPE
     
503. If Exist %RP%\MAOTAO Goto Err1
     
504. If Exist %PEDIR% Goto Err1
     
505. MyIns\NTBoot.exe %RP% >NUL
     
506. Echo.
     
507. Echo 正在复制文件，请稍候 。。。
     
508. If Exist %RP%\NTLDR %DelATTR% %RP%\NTLDR&&Ren %RP%\NTLDR NTLDR.BAK
     
509. Set NoLDR=Yes
     
510. If "%NoLDR%"=="Yes" MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% LDRXPE -r -y>NUL 2>NUL
     
511. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y>NUL 2>NUL
     
512. If "%NoLDR%"=="Yes" Ren %RP%\LDRXPE NTLDR
     
513. Call :CopyAndSetFiles
     
514. Goto SUCCESS
     
515. 
     
516. :CopyAndSetFiles
     
517. 
     
518. If Not Exist %RP%\NTLDR MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTLDR -r -y >NUL 2>NUL
     
519. If "%U%"=="" For /F %%i In ("%RP%\NTLDR") Do If %%~zi LSS 250000 Set SysVer=2K >NUL 2>NUL
     
520. If "%NoLDR%"=="" MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP%\%LDRP% LDRXPE -r -y >NUL 2>NUL
     
521. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% NTCOM -r -y>NUL 2>NUL            >NUL 2>NUL
     
522. ::If Not Exist %RP%\NTLDR MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTLDR -r -y  >NUL 2>NUL
     
523. 
     
524. echo.
     
525. Copy ..\%PEFile% %PEDIR% /Y /Z
     
526. Copy ..\%OPFile% %PEDIR% /Y /Z
     
527. Copy ..\%PEIni% %PEDIR% /Y  /Z
     
528. Copy ..\%DOSIMG% %PEDIR% /Y  /Z
     
529. If "%U%"=="" If Exist %RP%\BOOT.INI %DelATTR% %RP%\BOOT.INI
     
530. If "%U%"=="" If Exist %RP%\BOOT.INI If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK
     
531. If "%U%"=="" If Exist %RP%\BOOT.INI Copy %RP%\BOOT.INI %RP%\BOOT.BAK>NUL 2>NUL
     
532. If "%U%"=="" If Exist %RP%\BOOT.INI TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI
     
533. If "%U%"=="" If Exist %RP%\BOOT.INI Echo C:\MiniPE\MAOTAO.BIN="WinPE">>%RP%\BOOT.INI
     
534. If /I "%SysVer%"=="2K" (
     
535.         %DelATTR% %RP%\NTLDR&&%DelATTR% %RP%\bootfont.bin
     
536.         Ren %RP%\NTLDR NTLDR.2K&&Ren %RP%\bootfont.bin bootfont.bin.2K
     
537.         MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTLDR -r -y>NUL 2>NUL
     
538.         MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% bootfont.bin -r -y>NUL 2>NUL
     
539. )
     
540. If Exist %RP%\%PEIni% %DelATTR% %RP%\%PEIni%
     
541. TYPE ..\%PEIni%|FIND /I /V "PESetup.EXE">%RP%\%PEIni%
     
542. %AddATTR% %RP%\MiniPE /S /D
     
543. ::%AddATTR% %RP%\MiniPE\*.* /S /D
     
544. If Exist %RP%\BOOT.INI %AddATTR% %RP%\BOOT.INI
     
545. If Exist %RP%\%LDRP%LDRXPE %AddATTR% %RP%\%LDRP%LDRXPE
     
546. If Exist %RP%\MTLDR.PE %AddATTR% %RP%\MTLDR.PE
     
547. If Exist %RP%\nTLDR %AddATTR% %RP%\nTLDR
     
548. If Exist %RP%\mTLDR %AddATTR% %RP%\mTLDR
     
549. Goto :EOF
     
550. 
     
551. :SUCCESS
     
552. Title %Prog%——安装完成
     
553. CLS
     
554. For %%i In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do If /I "%RP%"=="%%i:" Set RP=%%i:
     
555. Echo 已经成功将镜像 %PEFile% 安装到您的 %RP% 盘。
     
556. If "%U%"=="" (
     
557. Echo.
     
558. If Exist %RP%\Boot.INI Echo 系统分区中的 BOOT.INI 备份为 BOOT.BAK。
     
559. )
     
560. Echo.&&Echo.
     
561. Echo 如果您需要将 WinPE 卸载，请重新运行本安装程序。
     
562. Echo.
     
563. Echo 请按任意键退出 。。。
     
564. PAUSE>NUL 2>NUL
     
565. Exit

复制代码

msuser

只将以下内容保存为批处理使用不会报毒的（就是看上去不那么顺眼）但只要使用EXESCRIT.EXE转为.EXE格式（顺眼了）就仍然会被劣质杀软报毒的。换个好点的杀软吧。
@Echo Off
COLOR 2F
Set Prog=老毛桃制作的 WinPE 专用安装工具
Set L1=　　　　　　╭══════════════════╮
Set L2=　　　　　　║　　　　　　　　　　　　　　　　　　║
Set L3=　　　╭══┤　%Prog%　 ├══╮
Set L4=　　　║　　║　　　　　　　　　　　　　　　　　　║　　║
Set L5=　　　║　　╰══════════════════╯　　║
Set L6=　　　║　　　　　　　　　　　　　　　　　　　　　　　　║
Set L7=　　　╟════════════════════════╢
Set L8=　　　║　版权所有：老毛桃　　仅供网友们交流　翻版不究　║
Set L9=　　　╰────────────────────────╯
Title %Prog%

Set SetupINIFile=PESetup.INI
Set PEFile=MiniPE\WinPE.IS_
Set PEIni=MiniPE\WinPE.INI
Set LogFile=PEInstall.log
If Not Exist .\PESETUP.INI Goto Err0
For /F "tokens=2 delims=^=" %%I In ('FIND /I ^"外置程序包^" .\%SetupINIFile%') DO Set OPFile=MiniPE\%%I

Set AddATTR=ATTRIB +S +H +R
Set DelATTR=ATTRIB -S -H -R

:Start
CLS
Title %Prog%——安装
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo 　　　║ 　请选择安装方式：　　　　　　　　　　　　　　 ║
Echo %L6%
Echo 　　　║　　[1] 普通安装/启动 (硬盘安装)　　　　　　　　║
Echo 　　　║　　[2] Grub安装/启动 (硬盘安装，支持 MD5 密码) ║
Echo 　　　║　　[3] Aero安装/启动 (硬盘安装，支持密码)　　　║
Echo 　　　║　　[4] Grub安装/启动 (U 盘、移动硬盘安装)　　　║
Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
Echo %L6%
Echo %L7%
Echo 　　　║　注意: Aero 安装项只适合系统分区在(HD0,0)分区　║
Echo %L7%
Echo %L8%
Echo %L9%
Echo.
Set Choice=
Set /P Choice=　　　请选择要进行的操作 (1/2/3/4/Q) ，然后按回车：
If "%Choice%"=="" Goto Start
If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
If /I "%Choice%"=="1" Goto HD
If /I "%Choice%"=="2" Goto HD
If /I "%Choice%"=="3" Goto HD
If /I "%Choice%"=="4" Goto UD
If /I "%Choice%"=="Q" Exit
Goto Start

:HD
Set RP=
For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BOOT.INI Set RP=%%I:
If "%RP%"=="" Goto HDRPErr
Set PEDIR=%RP%\MiniPE&&Set TargetP=硬盘&&Set TxtSp=
If Exist %PEDIR% Goto Err1
FIND /I "C:\MAOTAO" %RP%\BOOT.INI>NUL 2>NUL
If "%Errorlevel%"=="0" Goto Err1
FIND /I "C:\MiniPE" %RP%\BOOT.INI>NUL 2>NUL
If "%Errorlevel%"=="0" Goto Err1
If /I "%Choice%"=="1" Goto Install
If /I "%Choice%"=="2" Goto GInstall
If /I "%Choice%"=="3" Goto AInstall
Goto HD

:UD
CLS
Title %Prog%——U 盘安装
For /F "skip=2 tokens=*" %%I In ('MYINS\CHECKUSB.EXE') DO SET Us=%%I
If "%Us%"=="当前可移动磁盘分区：" Goto NoUD
Echo %Us%&&Echo.
If "%NoUD%"=="Yes" Echo 错误：您设定的分区 %RP% 不存在、写保护、未格式化或不是 U 盘分区，请按任意键重新设定。&&Echo.
Set /P RP=请选择您的 U 盘盘符（不需要冒号，例如 F）：
Echo.&&Echo.
If "%RP%"=="" Goto UD
If Not "%RP%"=="" Set RP=%RP:~0,1%:
For /F %%I In ('MYINS\CHECKUSB.EXE %RP%') DO SET Err2=%%I
If Not "%Err2%"=="1" Set NoUD=Yes&&Goto UD
Set TestFile=%RP%\MiniPETest_%RANDOM%.MT
Cd.>%TestFile%
If Not Exist %TestFile% Set NoUD=Yes&&Goto UD
Del %TestFile% /Q>NUL 2>NUL
Set U=U&&Set PEDIR=%RP%\MiniPE&&Set TargetP= U 盘&&Set TxtSp=
If Exist %RP%\MAOTAO Goto Err1
If Exist %PEDIR% Goto Err1
CLS
Echo 您选择的 U 盘分区为 %RP%，下面将对您的 U 盘进行格式化并写入引导
Echo.
Echo 请严格按照相关工具软件界面中的提示操作，以防出错。请按任意键开始。。。
PAUSE>NUL
Start /Wait MYINS\HPUSBFW.EXE
Start /Wait MYINS\GRUBGUI.EXE
Echo.
Echo 您的 U 盘已经成功格式化并写入了 Grub 引导，请按任意键继续。。。
PAUSE>NUL
Goto GInstall

:NoUD
CLS
Title %Prog%——U 盘安装
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo 　　　║ 您的计算机似乎没有安装 U 盘，您想怎么办？　　　║
Echo %L6%
Echo 　　　║　　[B] 返回首页，重新选择安装选项。　　　　　　║
Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
Echo %L6%
Echo %L7%
Echo %L8%
Echo %L9%
Echo.
Set Choice=
Set /P Choice=　　　请选择要进行的操作 (B/Q) ，然后按回车：
If "%Choice%"=="" Goto NoUD
If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
If /I "%Choice%"=="B" Goto Start
If /I "%Choice%"=="Q" Exit
Goto NoUD
Exit

:Err0
Echo 错误：安装配置文件丢失！&&Echo.
Echo 请确认安装配置文件 %SetupINIFile% 存在或到本程序所在目录执行安装。&&Echo.
Echo 请按任意键退出安装程序。。。
PAUSE>NUL
Exit

:Err1
CLS
Title %Prog%——卸载
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo 　　　║ 您的%TargetP%中好像已经安装了 WinPE，您想怎么办？%TxtSp%　║
Echo %L6%
Echo 　　　║　　[1] 卸载原有的 WinPE，并且重新安装。　　　　║
Echo 　　　║　　[2] 卸载原有的 WinPE，并且不再安装。　　　　║
Echo 　　　║　　[B] 返回首页，重新选择安装选项。　　　　　　║
Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
Echo %L6%
Echo %L7%
Echo %L8%
Echo %L9%
Echo.
Set Choice=
Set /P Choice=　　　请选择要进行的操作 (1/2/B/Q) ，然后按回车：
If "%TargetP%"=="硬盘" Set U=
If "%Choice%"=="" Goto Err1
If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
If /I "%Choice%"=="1" Set Choi=1&&Goto UnInstall
If /I "%Choice%"=="2" Goto UnInstall
If /I "%Choice%"=="B" Goto Start
If /I "%Choice%"=="Q" Exit
Goto Err1
Exit

:UnInstall
If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE&&Del %RP%\LDRXPE /Q>NUL 2>NUL
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE&&Del %RP%\WINNT.XPE /Q>NUL 2>NUL
If Exist %RP%\MTLDR.PE %DelATTR% %RP%\MTLDR.PE&&Del %RP%\MTLDR.PE /Q>NUL 2>NUL
If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR&&Del %RP%\MTLDR /Q>NUL 2>NUL
If Exist %RP%\%LogFile% For /F "eol=; tokens=2 delims=^=" %%i In ('find /I ^"WinPE外挂位置^" %RP%\%LogFile%') do SET OPD=%%i
If Not "%U%"=="" Set OPD=%RP%
If Exist %OPD%\外置程序 RD %OPD%\外置程序 /S /Q>NUL 2>NUL
If Exist %RP%\%LogFile% %DelATTR% %RP%\%LogFile%&&Del %RP%\%LogFile% /Q>NUL 2>NUL
If Exist %RP%\MAOTAO RD %RP%\MAOTAO /S /Q>NUL 2>NUL
If Exist %RP%\MiniPE RD %RP%\MiniPE /S /Q>NUL 2>NUL
%DelATTR% %RP%\BOOT.INI>NUL 2>NUL
Set TMPINIFile=BOOT_%RANDOM%.INI
If Exist %RP%\BOOT.BAK (
%DelATTR% %RP%\BOOT.BAK
TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MAOTAO">%RP%\%TMPINIFile%
TYPE %RP%\%TMPINIFile%|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI
) Else (
If Exist %RP%\BOOT.INI TYPE %RP%\BOOT.INI|FIND /I /V "C:\MAOTAO">%RP%\%TMPINIFile%
If Exist %RP%\%TMPINIFile% TYPE %RP%\%TMPINIFile%|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI
)
If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK&&Del %RP%\BOOT.BAK>NUL 2>NUL
If Exist %RP%\%TMPINIFile% %DelATTR% %RP%\%TMPINIFile%&&Del %RP%\%TMPINIFile%>NUL 2>NUL
If Exist %RP%\BOOT.INI %AddATTR% %RP%\BOOT.INI
Set RP=
Title %Prog%——卸载完成
If "%Choi%"=="1" (Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键准备安装 。。。&&PAUSE>NUL 2>NUL&&Goto Start)
Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键退出 。。。
PAUSE>NUL 2>NUL
Exit

:Install
Title %Prog%——普通安装
If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
Echo.&&Echo　　　　正在复制文件，请稍候 。。。
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% MAOTAO.BIN -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y>NUL 2>NUL
Call :CopyAndSetFiles
Goto SUCCESS

:GInstall
If "%U%"=="" Title %Prog%——Grub安装
CLS
Set LDRP=MiniPE\
Echo 请输入您要设定的密码
Echo 注意：密码中不许有空格、"\"、引号等特殊字符
Echo.
Set /P Pass1=请输入：
If "%Pass1%"=="" Goto GInstall
Echo.&&Echo.
Echo 请再一次输入您的密码
Echo.
Set /P Pass2=请再次输入：
If "%Pass2%"=="" Goto GInstall
If Not "%Pass2%"=="%Pass1%" Echo.&&Echo 您两次输入的密码不一致，请重新输入&&Echo 请按任意键重新开始设置密码&&PAUSE>NUL 2>NUL&&Goto GInstall
If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
>%PEDIR%\MD5P.TMP <nul Set/p=%Pass2%
MYINS\MD5.EXE %PEDIR%\MD5P.TMP %PEDIR%\MD5R.TXT>NUL 2>NUL
For /f %%i In ('type %PEDIR%\md5r.txt') do SET MD5Pass=password --md5 %%i
MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% MTLDR -r -y>NUL 2>NUL
>>%RP%\MTLDR Echo %MD5Pass%
>>%RP%\MTLDR Echo fontfile /minipe/muifont.gz
>>%RP%\MTLDR Echo splashimage /minipe/bj2008.xpm.gz
>>%RP%\MTLDR Echo.
>>%RP%\MTLDR Echo title WinPE 迷你维护系统 ^(By: MAOTAO^)
>>%RP%\MTLDR Echo %MD5Pass%
>>%RP%\MTLDR Echo chainloader /minipe/ldrxpe
>>%RP%\MTLDR Echo.
>>%RP%\MTLDR Echo title Grub 命令行
>>%RP%\MTLDR Echo %MD5Pass%
>>%RP%\MTLDR Echo commandline
>>%RP%\MTLDR Echo.
>>%RP%\MTLDR Echo title 从第一硬盘第一分区启动
>>%RP%\MTLDR Echo root ^(hd0,0^)
>>%RP%\MTLDR Echo chainloader +1
>>%RP%\MTLDR Echo.
>>%RP%\MTLDR Echo title 从第二硬盘第一分区启动
>>%RP%\MTLDR Echo root ^(hd1,0^)
>>%RP%\MTLDR Echo chainloader ^(hd1,0^)+1
>>%RP%\MTLDR Echo.
>>%RP%\MTLDR Echo title 重新启动计算机
>>%RP%\MTLDR Echo reboot
>>%RP%\MTLDR Echo.
>>%RP%\MTLDR Echo title 关闭计算机
>>%RP%\MTLDR <nul Set/p=halt
Del %PEDIR%\MD5?.* /Q>NUL 2>NUL
Echo.
Echo 密码设置完成，请牢记您的密码，并按任意键继续 。。。
PAUSE>NUL 2>NUL
If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR
Echo.
Echo 正在复制文件，请稍候 。。。
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% BJ2008.XPM.GZ -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% muifont.gz -r -y>NUL 2>NUL
If "%U%"=="" MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR%\ maotaog.bin -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y>NUL 2>NUL
If "%U%"=="" Ren %PEDIR%\maotaog.bin maotao.bin
Call :CopyAndSetFiles
Goto SUCCESS

:AInstall
Title %Prog%——Aero安装
CLS
Echo 请输入您要设定的密码
Echo 注意：密码中不许有空格、"\"、引号等特殊字符
Echo.
Set /P Pass1=请输入：
If "%Pass1%"=="" Goto AInstall
Echo.&&Echo.
Echo 请再一次输入您的密码
Echo.
Set /P Pass2=请再次输入：
If "%Pass2%"=="" Goto AInstall
If Not "%Pass2%"=="%Pass1%" Echo.&&Echo 您两次输入的密码不一致，请重新输入&&Echo 请按任意键重新开始设置密码&&PAUSE>NUL 2>NUL&&Goto AInstall
If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
For /f %%i In (MyIns\Aero.sys) Do MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% %%i -r -y>NUL 2>NUL
Ren %PEDIR%\maotao.bin avldr.xpe
Ren %PEDIR%\maotaoa.bin maotao.bin
>%PEDIR%\airL.gz <nul Set/p=%Pass2%
Copy /B %PEDIR%\airT.gz+%PEDIR%\airL.gz+%PEDIR%\airW.gz %PEDIR%\airmenu.ini>NUL 2>NUL&&Del %PEDIR%\air?.gz /Q>NUL 2>NUL>NUL 2>NUL
MyIns\MyIns.exe a -tGZip %PEDIR%\airmenu.gz %PEDIR%\airmenu.ini -w%PEDIR%>NUL 2>NUL&&Del %PEDIR%\airmenu.ini /Q>NUL 2>NUL&&Ren %PEDIR%\airmenu.gz airmenu.ini>NUL 2>NUL
Echo.
Echo 密码设置完成，请牢记您的密码，并按任意键继续 。。。
PAUSE>NUL 2>NUL
If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
Echo.
Echo 正在复制文件，请稍候 。。。
MOVE %PEDIR%\MTLDR.PE %RP%\>NUL 2>NUL
Call :CopyAndSetFiles
Goto SUCCESS

:HDRPErr
CLS
Set RP=
For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BootMGR Set RP=%%I:&&Set PEDIR=%%I:\MiniPE
If Not "%RP%"=="" (
        TITLE %Prog%——检测到 Windows Vista 分区
        Set OPT=Vista&&Set OPT0=存在 WinVista 分区&&Set OPT1=[I] 将 WimPE 安装到 Windows Vista 分区。
) Else (
        TITLE %Prog%——没有检测到系统分区
        Set OPT=NewHD&&Set OPT0=没有安装过操作系统&&Set OPT1=[I] 全新硬盘，将 WimPE 安装到活动分区。
)
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo 　　　║　好像您的机器中%OPT0%，您想怎么办？║
Echo %L6%
Echo 　　　║　　%OPT1%　　║
Echo 　　　║　　[B] 返回首页，重新选择安装选项。　　　　　　║
Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
Echo %L6%
Echo 　　　║　注意: 为确保安全，此安装选项可能会卸载不干净！║
Echo %L7%
Echo %L8%
Echo %L9%
Echo.
Set Choice=
Set /P Choice=　　　请选择要进行的操作 (I/B/Q) ，然后按回车：
If "%Choice%"=="" Goto HDRPErr
If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
If /I "%Choice%"=="I" If "%OPT%"=="Vista" Goto Vista
If /I "%Choice%"=="I" If "%OPT%"=="NewHD" Goto NewHD
If /I "%Choice%"=="B" Goto Start
If /I "%Choice%"=="Q" Exit
Goto HDRPErr
Exit

:Vista
Set PEDIR=%RP%\MiniPE
If Exist %RP%\MAOTAO Goto Err1
If Exist %PEDIR% Goto Err1
Echo.&&Echo.
Echo　　　　正在复制文件，请稍候 。。。
If Exist %RP%\NTLDR %DelATTR% %RP%\NTLDR&&Ren %RP%\NTLDR NTLDR.BAK
Set NoLDR=Yes
If "%NoLDR%"=="Yes" MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% LDRXPE -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y>NUL 2>NUL
If "%NoLDR%"=="Yes" Ren %RP%\LDRXPE NTLDR
Call :CopyAndSetFiles
Goto SUCCESS

:NewHD
CLS
TITLE %Prog%——在全新硬盘中安装
If "%NoNewErr%"=="Yes" Echo 错误：您设定的分区 %RP% 不存在、写保护、或未格式化，请按任意键重新设定。&&Echo.
Echo 请设置您需要安装 WinPE 到哪个分区（注意一定要是活动分区）
Echo.
Set /P RP=请输入您需要安装 WinPE 的分区符（不需要冒号，例如 C），然后按回车：
Echo.&&Echo.
If "%RP%"=="" Goto NewHD
If Not "%RP%"=="" Set RP=%RP:~0,1%:
For /F %%I In ('MYINS\CHECKUSB.EXE %RP%') DO SET Err2=%%I
If Not Exist %RP% Set NoNewErr=Yes&&Goto NewHD
Set TestFile=%RP%\MiniPETest_%RANDOM%.MT
Cd.>%TestFile%
If Not Exist %TestFile% Set NoNewErr=Yes&&Goto NewHD
Del %TestFile% /Q>NUL 2>NUL
Set PEDIR=%RP%\MiniPE
If Exist %RP%\MAOTAO Goto Err1
If Exist %PEDIR% Goto Err1
MyIns\NTBoot.exe %RP% >NUL
Echo.
Echo 正在复制文件，请稍候 。。。
If Exist %RP%\NTLDR %DelATTR% %RP%\NTLDR&&Ren %RP%\NTLDR NTLDR.BAK
Set NoLDR=Yes
If "%NoLDR%"=="Yes" MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% LDRXPE -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y>NUL 2>NUL
If "%NoLDR%"=="Yes" Ren %RP%\LDRXPE NTLDR
Call :CopyAndSetFiles
Goto SUCCESS

:CopyAndSetFiles
If Not Exist %RP%\NTLDR MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTLDR -r -y>NUL 2>NUL
If "%U%"=="" For /F %%i In ("%RP%\NTLDR") Do If %%~zi LSS 250000 Set SysVer=2K
If "%NoLDR%"=="" MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP%\%LDRP% LDRXPE -r -y>NUL 2>NUL
MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% NTCOM -r -y>NUL 2>NUL
::If Not Exist %RP%\NTLDR MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTLDR -r -y>NUL 2>NUL
Copy ..\%PEFile% %PEDIR% /Y>NUL 2>NUL
Copy ..\%OPFile% %PEDIR% /Y>NUL 2>NUL
Copy ..\%PEIni% %PEDIR% /Y>NUL 2>NUL
If "%U%"=="" If Exist %RP%\BOOT.INI %DelATTR% %RP%\BOOT.INI
If "%U%"=="" If Exist %RP%\BOOT.INI If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK
If "%U%"=="" If Exist %RP%\BOOT.INI Copy %RP%\BOOT.INI %RP%\BOOT.BAK>NUL 2>NUL
If "%U%"=="" If Exist %RP%\BOOT.INI TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI
If "%U%"=="" If Exist %RP%\BOOT.INI Echo C:\MiniPE\MAOTAO.BIN="WinPE  By: 老毛桃">>%RP%\BOOT.INI
If /I "%SysVer%"=="2K" (
        %DelATTR% %RP%\NTLDR&&%DelATTR% %RP%\bootfont.bin
        Ren %RP%\NTLDR NTLDR.2K&&Ren %RP%\bootfont.bin bootfont.bin.2K
        MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTLDR -r -y>NUL 2>NUL
        MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% bootfont.bin -r -y>NUL 2>NUL
)
If Exist %RP%\%PEIni% %DelATTR% %RP%\%PEIni%
TYPE ..\%PEIni%|FIND /I /V "PESetup.EXE">%RP%\%PEIni%
%AddATTR% %RP%\MiniPE /S /D
%AddATTR% %RP%\MiniPE\*.* /S /D
If Exist %RP%\BOOT.INI %AddATTR% %RP%\BOOT.INI
If Exist %RP%\%LDRP%LDRXPE %AddATTR% %RP%\%LDRP%LDRXPE
If Exist %RP%\MTLDR.PE %AddATTR% %RP%\MTLDR.PE
If Exist %RP%\MTLDR %AddATTR% %RP%\MTLDR
If Exist %RP%\NTLDR %AddATTR% %RP%\NTLDR
Goto :EOF

:SUCCESS
Title %Prog%——安装完成
CLS
For %%i In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do If /I "%RP%"=="%%i:" Set RP=%%i:
Echo 已经成功将镜像 %PEFile% 安装到您的 %RP% 盘。
If "%U%"=="" (
Echo.
If Exist %RP%\Boot.INI Echo 系统分区中的 BOOT.INI 备份为 BOOT.BAK。
)
Echo.&&Echo.
Echo 如果您需要将 WinPE 卸载，请重新运行本安装程序。
Echo.
Echo 请按任意键退出 。。。
PAUSE>NUL 2>NUL
Exit

xsllei

多谢 楼上的2楼 3 楼的 大哥...

不过2楼大哥转过来的 貌似不能用在 911上..提示复制文件失败..

3楼大哥的 可以使用..

在此谢过！！！

版主看到请锁帖.

阿卡特

多谢分享,十分感谢.但我没911..