0406更新【启动ISO映像制作程序】可制作多种启动ISO映像和 PE内核ISO - 无忧启动论坛

@Echo off
::2010.04.06更新 by caomaoLBL
::syslinux(isolinux)为3.86版
::英文版的grldr为03.29版，中文版的grldr依然是03.11版
::中文版grldr没更新的原因是：重新用UI编辑会有问题
::生成grub 引导的ISO 使用的是mkisofs
COLOR 1e
Set Prog= 启动ISO映像制作程序
Set L1=　　　　　　╭══════════════════╮
Set L2=　　　　　　║　　　　　　　　　　　　　　　　　　║
Set L3=　　　╭══┤ %Prog%　 ├══╮
Set L4=　　　║　　║　　　　　　　　　　　　　　　　　　║　　║
Set L5=　　　║　　╰══════════════════╯　　║
Set L6=　　　║　　　　　　　　　　　　　　　　　　　　　　　　║
Set L7=　　　╟════════════════════════╢
Set L8=　　　║　版权所有：caomaoLBL 无忧启动论坛　║
Set L9=　　　╰────────────────────────╯
Title %Prog%
::checkos
if /i not "%os%."=="windows_nt." goto systemerro
::判断系统版本并设置theos
ver|find /i " 6.1">nul &&set winver=7&& set theos=7
ver|find /i " 6.0">nul &&set winver=vista&& set theos=vista
ver|find /i " 5.0">nul &&set winver=winnt&& set theos=2000
ver|find /i " 5.1">nul &&set winver=winnt&& set theos=xp
ver|find /i " 5.2">nul &&set winver=winnt&& set theos=2003
goto start
:systemerro
cls
echo.
echo.
echo 注意：未经测试，本软件可能不适用于非 windows pe/2000/xp/2003/vista/7 操作系统。
echo 按回车键退出安装程序
pause >nul
exit
:Start
Title %Prog%——制作
CLS
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo 　　　║ 请选择生成方式：　　　　　　　　　　　　　 ║
Echo %L6%
Echo 　　　║ [1] 生成 Grub4dos英文版启动 ISO映像 ║
Echo 　　　║ [2] 生成 Grub4dos中文版启动 ISO映像 ║
Echo 　　　║ [3] 生成 Grub4dosGfxmenu启动 ISO映像 ║
Echo 　　　║ [4] 生成 Isolinux启动 ISO映像 ║
Echo 　　　║ [5] 生成 ISO格式PE内核 ISO映像 ║
Echo 　　　║ [6] 生成纯PE启动 ISO映像 ║
Echo 　　　║ [7] 生成 EZboot启动 ISO映像 ║
Echo 　　　║ [8] 生成 Bootmgr启动 ISO映像 ║
Echo 　　　║ [Q] 退出　　　　　　　　　　　　 ║
Echo %L6%
Echo %L7%
Echo %L8%
Echo %L9%
echo.
echo　　　您现在使用的是 windows %theos% 操作系统！
echo.
::Set Choice=
Set /P Choice=　　　请选择要进行的操作 (1/2/3/4/5/6/7/8/Q) ，然后按回车：
If "%Choice%"=="" GOTO Start
If Not "%Choice%"=="" SET Choice=%Choice:~0,1%
If /I "%Choice%"=="1" GOTO Gruben
If /I "%Choice%"=="2" GOTO Grubchs
If /I "%Choice%"=="3" GOTO Grubgfx
If /I "%Choice%"=="4" GOTO Isolinux
If /I "%Choice%"=="5" GOTO Neihe
If /I "%Choice%"=="6" GOTO PEiso
If /I "%Choice%"=="7" GOTO EZboot
If /I "%Choice%"=="8" GOTO Bootmgr
If /I "%Choice%"=="q" EXIT
Goto Start
:Gruben
Bin\mkisofs.exe -o Gruben.iso -V "GRUBEN" -quiet -no-emul-boot -boot-load-size 4 -J -O -R -N -l -hide boot.catalog -hide-joliet boot.catalog -relaxed-filenames -gbk4dos-filenames -gbk4win-filenames -b grldr Project/Gruben
::::::::::::::Bin\oscdimg.exe -h -m -o -d -l"GRUBEN" -n -b"Bin\grldr.bif" -t03/09/2010,00:00:00 -x "Project\Gruben" "Gruben.iso"
Goto :Success
:Grubchs
Bin\mkisofs.exe -o Grubchs.iso -V "GRUBCHS" -quiet -no-emul-boot -boot-load-size 4 -J -O -R -N -l -hide boot.catalog -hide-joliet boot.catalog -relaxed-filenames -gbk4dos-filenames -gbk4win-filenames -b grldr Project/Grubchs
::::::::::::::Bin\oscdimg.exe -h -m -o -d -l"GRUBCHS" -n -b"Bin\grchs.bif" -t03/09/2010,00:00:00 -x "Project\Grubchs" "Grubchs.iso"
Goto :Success
:Grubgfx
Bin\mkisofs.exe -o Grubgfx.iso -V "GRUBGFX" -quiet -no-emul-boot -boot-load-size 4 -J -O -R -N -l -hide boot.catalog -hide-joliet boot.catalog -relaxed-filenames -gbk4dos-filenames -gbk4win-filenames -b grldr Project/Grubgfx
::::::::::::::Bin\oscdimg.exe -h -m -o -d -l"GRUBGFX" -n -b"Bin\grgfx.bif" -t03/09/2010,00:00:00 -x "Project\Grubgfx" "Grubgfx.iso"
Goto :Success
:Isolinux
Bin\oscdimg.exe -h -m -o -d -l"ISOLINUX" -n -b"Bin\isolinux.bin" -t03/09/2010,00:00:00 -x "Project\Isolinux" "Isolinux.iso"
Goto :Success
:Neihe
Bin\oscdimg.exe -h -m -o -l"WINPE" -n -t03/19/2010,00:00:00 -x "Project\NeiHe" "WinPE.ISO"
Goto :Success
:PEiso
Bin\oscdimg.exe -h -m -o -l"BOOTCD" -n -b"Bin\pe.bif" -t03/19/2010,00:00:00 -x "Project\PEiso" "BOOTCD.iso"
Goto :Success
:EZboot
Bin\oscdimg.exe -h -m -o -d -l"EZBOOT" -n -b"Project\EZboot\boot\loader.bin" -t03/09/2010,00:00:00 -x "Project\EZboot" "EZboot.iso"
Goto :Success
:Bootmgr
Bin\oscdimg.exe -h -m -o -d -l"NT6.X" -n -b"Bin\bootmgr.bif" -t03/09/2010,00:00:00 -x "Project\NT6.X" "NT6.X.iso"
Goto :Success
:Success
title %prog%——制作完成
cls
echo.
echo.ISO映像已制作成功，就在当前目录下...
echo.
set /p cho=返回主菜单继续制作请输入Y，否则按Enter(回车)退出。
if /i "%cho%"=="y" call :start
exit

复制代码