公交线路查询器

namejm

　　在英汉互译器的基础上更进一步，批处理版的公交信息查询系统就出笼啦：

1. 
   
2. @echo off
   
3. title 公交线路查询器-test
   
4. setlocal enabledelayedexpansion
   
5. goto begin
   
6. 
   
7. 功能：
   
8. 　　① 输入线路名称，显示该线路的所有站点及发车收车时间；
   
9. 　　② 输入上车站点和下车站点，显示可直达的车次，并显示每条线路中这两个站点及其之间的所有站点及发车收车时间；
   
10. 　　③ 可查询换乘线路
    
11. 
    
12. 流程：
    
13. 　　1、输入查询对象；
    
14.     2、判断输入类型：若为数字、数字+字母，则查询车次；若带汉字，则查询站点信息；
    
15. 　　3、若查询车次，有则显示，无则提示重新查询；
    
16. 　　4、若查询站点，首先检测是否存在此站点；若不存在，则提示换用近似的站点查询；若存在该站点，有直达则只显示直达，无直达则查询换乘；若无换乘，则提示重新查询，此时罗列近似的起止站点供选择；
    
17. 
    
18. code by JM 2006-10-17～11-17   CMD@XP
    
19. 
    
20. :begin
    
21. cls
    
22. set input=
    
23. set /p input=请输入车次或上、下车站点：
    
24. :: 车次只允许输入数字或数字+字母，否则会认为是站点
    
25. echo %input%|findstr /r "^[0-9][0-9]*[a-zA-Z]*$">nul &&(
    
26.     call :get_line %input%
    
27.     echo !num!
    
28.     echo !_time!
    
29.     echo !line_info:~1,-1!
    
30.     goto end
    
31. )
    
32. call :find_station %input%
    
33. 
    
34. rem ========== 查询车次编号匹配的线路信息 ==========
    
35. 
    
36. :get_line
    
37. :: 获取要查询的车次编号所在的行
    
38. cls
    
39. set line=
    
40. for /f "tokens=1* delims=:" %%i in ('findstr /nr "^%1路：$" 公交线路.txt') do (
    
41.     set line=%%i
    
42.     if not "!line!"=="" goto get_block
    
43. )
    
44. goto no-item
    
45. 
    
46. rem ========== 查询直达方案 ==========
    
47. 
    
48. :find_station
    
49. :: 只允许同时输入两个站点
    
50. if "%2"=="" goto begin
    
51. if not "%3"=="" goto begin
    
52. find "-%1-" 公交线路.txt>nul||goto no-start
    
53. find "-%2-" 公交线路.txt>nul||goto no-end
    
54. cls
    
55. set line=
    
56. set str=
    
57. set var=
    
58. for /f "tokens=1* delims=:" %%i in ('findstr /n "\-%1\-" 公交线路.txt') do (
    
59.     set line=%%i
    
60.     set str=%%j
    
61.     set str=!str:-%2-=!
    
62.     if not "!str!"=="%%j" (
    
63.         set var=%%j
    
64.         set var=!var:-%1-=-☆%1☆-!
    
65.         set var=!var:-%2-=-☆%2☆-!
    
66.         call :pick-up %input% !var!
    
67.         call :type_nostop
    
68.     )
    
69. )
    
70. :: 如果没找到直达线路，则查询换乘方案
    
71. if "%var%"=="" call :transfer %input%
    
72. 
    
73. :end
    
74. pause
    
75. goto begin
    
76. 
    
77. rem ========== 查询换乘方案 ==========
    
78. 
    
79. :: 换乘线路只能查到匹配的第一条，可能不是最短线路
    
80. :transfer
    
81. set first_line=
    
82. set first_id=
    
83. set first_time=
    
84. set second_line=
    
85. set second_id=
    
86. set second_time=
    
87. set link=
    
88. for /f "tokens=1* delims=:" %%i in ('findstr /n "\-%1\-" 公交线路.txt') do (
    
89.     set first_line=%%i&set str_start=%%j
    
90.     set stations_start=!str_start:-= !
    
91.     for /f "tokens=1* delims=:" %%k in ('findstr /n "\-%2\-" 公交线路.txt') do (
    
92.         set second_line=%%k&set str_end=%%l
    
93.         set stations_end=!str_end:-= !
    
94.         for %%m in (!stations_start!) do (
    
95.             for %%n in (!stations_end!) do (
    
96.                 if "%%m"=="%%n" (
    
97.                     set link=%%m
    
98.                     set /a line=!first_line!-2&&call :get_block
    
99.                     set first_id=!num!
    
100.                     set first_time=!_time!
     
101.                     set /a line=!second_line!-2&&call :get_block
     
102.                     set second_id=!num!
     
103.                     set second_time=!_time!
     
104.                     goto type_change
     
105.                 )
     
106.             )
     
107.         )
     
108.     )
     
109. )
     
110. if "%link%"=="" goto no-change
     
111. 
     
112. 
     
113. rem ━━━━━━━━━━━ 子过程 ━━━━━━━━━━━
     
114. 
     
115. rem ========== 获取某条线路的完整信息 ==========
     
116. :get_block
     
117. set /a line-=1
     
118. set count=
     
119. for /f "skip=%line%" %%i in (公交线路.txt) do (
     
120.     set /a count+=1
     
121.     if !count! equ 1 set num=%%i
     
122.     if !count! equ 2 set _time=%%i
     
123.     if !count! equ 3 set line_info=%%i
     
124.     if !count! gtr 3 goto :eof
     
125. )
     
126. 
     
127. rem ========== 提取上车站点到下车站点之间的所有站点 ==========
     
128. :pick-up
     
129. for /f "tokens=2-4 delims=☆" %%i in ("%3") do set var=%%i%%j%%k
     
130. :: 判断输入的起止点在 公交线路.txt 中的先后顺序
     
131. :: 以决定是否逆向显示相关信息
     
132. for /f "tokens=1 delims=-" %%i in ("!var!") do if "%%i"=="%2" call :reverse
     
133. goto :eof
     
134. 
     
135. rem ========== 显示直达方案信息 ==========
     
136. 
     
137. :type_nostop
     
138. set /a line-=2
     
139. call :get_block
     
140. echo 乘坐 %num:~0,-2% 路车(%_time%)：%var%
     
141. echo.
     
142. goto :eof
     
143. 
     
144. rem ========== 显示换乘方案信息 ==========
     
145. :type_change
     
146. echo 交汇点是 %link%
     
147. echo.
     
148. set str_start=!str_start:-%1-=-☆%1☆-!
     
149. set str_start=!str_start:-%link%-=-☆%link%☆-!
     
150. echo 先搭乘 %first_id:~0,-2% 路在 %link% 站下车，然后换乘 %second_id:~0,-2% 路即可，换乘方案为：
     
151. echo.
     
152. call :pick-up %1 %link% %str_start%
     
153. echo %first_id:~0,-2%路(%first_time%)： %var%
     
154. set str_end=!str_end:-%2-=-☆%2☆-!
     
155. set str_end=!str_end:-%link%-=-☆%link%☆-!
     
156. echo.
     
157. call :pick-up %1 %2 %str_end%
     
158. echo %second_id:~0,-2%路(%second_time%)： %var%
     
159. echo _____________________________________________________________
     
160. goto :eof
     
161. 
     
162. rem ========== 逆向显示站点信息 ==========
     
163. :reverse
     
164. set var=%var:-= %
     
165. set str=
     
166. for %%i in (%var%) do set str=%%i-!str!
     
167. set var=%str:~0,-1%
     
168. goto :eof
     
169. 
     
170. 
     
171. 
     
172. rem ━━━━━━━━━━━ 出错信息 ━━━━━━━━━━━
     
173. 
     
174. :no-start
     
175. cls
     
176. echo 没有找到名为 "%1" 的上车站点
     
177. pause
     
178. goto begin
     
179. 
     
180. :no-end
     
181. cls
     
182. echo 没有找到名为 "%2" 的下车站点
     
183. pause
     
184. goto begin
     
185. 
     
186. :no-change
     
187. echo 没有找到直达线路，也找不到只转一次车的换乘方案
     
188. pause
     
189. goto begin
     
190. 
     
191. :no-item
     
192. echo 没有找到车次编号为 "%input%" 的相关信息，请重新查阅.
     
193. pause
     
194. goto begin
     

复制代码

　　公交线路.txt 格式举例：

1. 
   
2. 线路信息格式为：
   
3. 　　①　文本正文首行不能为线路信息，可以设为空，或其他内容；
   
4. 　　②  每条线路第一行为线路编号，格式为"数字+路："(如11路：)或 数字+字母+路：(如503A路：)，必须是中文半角状态下的冒号；第二行为发、收车时间；第三行为经过的站点，每个站点用短横线括起来，(如：-川大-电子科大-)；
   
5.     ③  每条线路的信息块之间只能用空行分隔，或者不分隔；
   
6. 　　④  除了站点、时间之间用-分隔之外，其他行不能再出现-；
   
7. 
   
8. ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
   
9. 
   
10. 1路：
    
11. 6:00-23:00
    
12. -青龙场中心站-昭觉寺横街-洪家坡-驷马桥-高笋桥-解放路一段-梁家巷-好又多府河店-北大街-中西顺城街-盐市口-红照壁-南大街-浆洗街-南郊路-武侯祠-高升桥-高升桥路中段-佳灵路-川藏路高新路口-太平园-八一家具城-
    
13. 
    
14. 2路：
    
15. 5:45-22:30
    
16. -火车北站-荷花池-高笋塘-二环路北四段-二环路东一段北-二环路东一段中-二环路东一段南-麻石桥-二环路东三段中-万年场-双林中横路-双桥子-塔子山-五桂桥-
    
17. 
    
18. 3路：
    
19. 6:15-23:00
    
20. -桦林园-红砖桥-沙河大桥-东光小区-二环路东五段-三官堂-顺江路-九眼桥-牛王庙-水碾河-东风大桥-大慈寺路-总府路东-文化宫-太升路口-青羊二医院-江汉路东-江汉路西-通锦桥-沙湾路-会展中心-西南交大-交大路西-香榭里-九里堤公交总站-
    
21. 
    
22. 4路：
    
23. 5:50-23:00
    
24. -五桂桥-双桥子-水碾河-东风大桥-大慈寺路-总府路东-总府路-人民西路-东城根上街-羊市街-西大街-西月城街-花牌坊街-西门车站-营门口立交桥-五里村-茶店子-茶店子西-三环路成灌路立交桥南-茶店子公交站-
    

复制代码

tousy

收藏学习，谢谢分享！

xinyubbl

不错，收藏了。

mackyliu

全部收藏,今天没白来.哈哈