无忧启动论坛

标题: 【批处理】通过FINDSTR控制CMD命令行显示文字颜色 [打印本页]
作者: 201287zr    时间: 2025-3-12 23:39
标题: 【批处理】通过FINDSTR控制CMD命令行显示文字颜色
本帖最后由 201287zr 于 2025-3-13 10:01 编辑

前段时间看到论坛有人分享利用ANSI控制cmd显示字符颜色，这里我也分享一个利用FINDSTR.EXE来控制CMD显示字符颜色的批处理，可以支持xp—win11。这是以前学批处理时在网上搜到的一个方法，个人只是对其进行了简单优化，让它可以显示部分特殊字符。
1.使用方法
将下面的批处理脚本添加到你自己批处理文件的末尾，并主程序的合适位置通过CALL调用，就可以显示文字颜色。
CALL :colortxt 颜色代码 “字符串” [/n]

2.功能说明
colortxt可处理3个参数：颜色值 "字符串" /n
颜色值 指定控制台输出的颜色属性，可查阅 color /? 命令
字符串 要显示（输出）的文字，最好使用""将文字包围起来
/n        显示时进行换行，如果不加此参数默认不会自动换行
注意：要显示的字符串不要超过72个英文字符，否则cmd行尾会显示多余的\..\':.字符。
脚本支持显示^//|&\<*>等特殊字符，要显示（输出）一个%，请用%%%%代替。

  1. @ECHO OFF
  2. REM CMD中显示字符串颜色 By 初一的阳光

  4. REM ===========================在主程序中调用===========================
  5. SET var=Hello World
  6. REM 用法为CALL :colortxt 颜色代码 “要显示的文字” [/n]
  7. CALL :colortxt E4 "%var% (!^/|&\<*>%%%%:!)" /n
  8. CALL :colortxt 4E "不自动换行"
  9. ECHO 这是正常文字颜色

  11. REM 调用colortxt后执行清理工作
  12. CALL :cleanupTmpFile

  14. pause&exit


  17. REM ===========================字符串颜色处理===========================
  18. :colortxt
  19. SET "str_=%~2"
  20. SET "str_=%str_:!=^!%"

  22. :colorPrint Color  Str  [/n]
  23. @ECHO OFF&SETLOCAL ENABLEDELAYEDEXPANSION
  24. CALL :colorPrintVar %1 str_ %3
  25. ENDLOCAL
  26. EXIT /B

  28. :colorPrintVar Color  StrVar  [/n]
  29. SET "str_=!%~2!"
  30. IF NOT DEFINED DEL CALL :initColorPrint
  31. PUSHD ':
  32. REM 不要删除下面FOR语句中的空行
  33. FOR %%n IN (^"^

  35. ^") DO (
  36.   SET "str_=!str_:\=%%~n\%%~n!"
  37.   SET "str_=!str_:/=%%~n/%%~n!"
  38.   REM SET "str_=!str_::=%%~n:%%~n!"
  39. )

  41. FOR /F delims^=^ eol^= %%s IN ("!str_!") DO (
  42.   IF [%%s]==[\] (
  43.     FINDSTR /A:%1 "." "\'" NUL & SET/P "=%DEL%%DEL%%DEL%" <nul
  44.   ) ELSE IF [%%s]==[/] (
  45.     FINDSTR /A:%1 "." "/.\'" NUL & SET/P "=%DEL%%DEL%%DEL%%DEL%%DEL%"<nul
  46.   ) ELSE (
  47.     >colorPrint.txt ECHO %%s\..\'
  48.     FINDSTR /A:%1 /F:colorPrint.txt "." & SET/P "=%DEL%%DEL%%DEL%%DEL%%DEL%%DEL%%DEL%"<NUL
  49.   )
  50. )
  51. IF /I [%~3]==[/n] ECHO.
  52. IF /I [%~3]==[\n] ECHO.
  53. IF /I [%~3]==[-n] ECHO.
  54. POPD
  55. EXIT /B

  57. :initColorPrint
  58. SET PROMPTDEL="prompt $H&for %%i in (1) do rem THISISIMORTANT"
  59. FOR /F %%A IN ('%PROMPTDEL%') DO SET "DEL=%%A %%A"
  60. IF NOT EXIST ':\ (SUBST ': "%temp%" >NUL)
  61. >"%temp%\'" SET /P "=."<NUL
  62. EXIT /B

  64. :cleanupTmpFile
  65. 2>NUL DEL /F /Q "%temp%\'"
  66. 2>NUL DEL "%temp%\colorPrint.txt"
  67. SUBST ': /D >NUL
  68. EXIT /B %ERRORLEVEL%
复制代码



FINDSTR显示颜色核心原理：
REM FINDSTR /A:颜色属性 "搜索字符串" 文件列表（只有在搜索多个文件时才会显示颜色）
REM FINDSTR只会显示“相对路径及其文件名”的颜色，而查找到的字符串不会显示颜色
REM FINDSTR /F表示从指定文件中读取文件列表，列表中/表示控制台输入，\会被解析为路径

以上代码其实还包含了很多批处理技巧，比如相对路径运用、预处理、FOR循环、CALL调用等，对于学习提高批处理技巧有很大的帮助！
希望大家喜欢，共同探讨交流，分享宝贵经验！




作者: 小灰兔    时间: 2025-3-13 07:23
感谢分享
作者: wang1126    时间: 2025-3-13 08:19
谢谢楼主分享
作者: yc2428    时间: 2025-3-13 08:36
感谢分享
作者: wn168cn@163.com    时间: 2025-3-13 08:39
很好
作者: dksoft    时间: 2025-3-13 08:40
感谢分享
作者: BEIKING    时间: 2025-3-13 09:06
感谢分享。。。
作者: BEIKING    时间: 2025-3-13 10:30
这里面最牛逼的是哪个神人想出来的 Subst ': "%temp%"
作者: plutoshen    时间: 2025-3-13 12:07
提示: 作者被禁止或删除 内容自动屏蔽
作者: 旭东    时间: 5 天前
感谢分享
作者: tanchenglong    时间: 5 天前
啥也不说了，帖子就是带劲！



欢迎光临 无忧启动论坛 (http://wuyou.net./) Powered by Discuz! X3.3