自娱自乐自用 CMD命令设置或添加PE启动项

享β亻寸木东

1. @echo off &title  _ CMD 设置 PE _
   
2. %1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
   
3. PUSHD %~dp0
   
4. ::获取管理员权限
   
5. 
   
6. set mode=2
   
7. ::改成0 加入启动菜单，每次启动系统时都可以选择
   
8. ::改成1 一次性启动
   
9. ::改成2 显示设置页面，两种模式自己选择
   
10. if /i "%mode%"=="0" goto:mode0
    
11. if /i "%mode%"=="1" goto:mode1
    
12. if /i "%mode%"=="2" goto:mode2
    
13. echo.&echo mode参数不对，请重新设置。按任意键退出 &pause >nul&exit
    
14. 
    
15. :mode0
    
16. cls
    
17. Call :bcdedit
    
18. bcdedit /displayorder %Guid% -addlast >nul 2>&1
    
19. ::把PE加入启动列表。
    
20. bcdedit /timeout 5
    
21. ::设置等待时间为 5 秒（可更改）
    
22. cls &echo.&echo  PE启动项添加完成。按任意键退出。&pause >nul&exit
    
23. 
    
24. :mode1
    
25. cls
    
26. Call :bcdedit
    
27. bcdedit /bootsequence %Guid% >nul 2>&1
    
28. ::重启后进入此PE（一次性的）。
    
29. cls &echo.&echo 设置完成，按任意键重启，并进入PE。&pause >nul
    
30. ::删除此行，立即重启进入PE。
    
31. shutdown -r -t 0
    
32. ::立即重启
    
33. exit /b
    
34. 
    
35. :mode2
    
36. ECHO.
    
37. ECHO.         按数字 0  把PE加入启动列表
    
38. ECHO.
    
39. ECHO.         按数字 1  进入一次性PE
    
40. ECHO.
    
41. ECHO.
    
42. choice /C:01 /N /M ">输入你的选择："
    
43. if errorlevel  2 goto:mode1
    
44. if errorlevel  1 goto:mode0
    
45. 
    
46. :bcdedit
    
47. cls &echo.&echo 正在处理……
    
48. md "C:\PE" >nul 2>&1
    
49. ::在C盘新建PE文件夹
    
50. if not exist boot.sdi (cls &echo.&echo 未找到boot.sdi文件，请把文件和此脚本放一起。按任意键退出。&pause >nul&exit)
    
51. xcopy boot.sdi "C:\PE" /Y /Q >nul 2>&1
    
52. ::复制boot.sdi文件到"C:\PE"文件夹
    
53. if not exist boot.wim (cls &echo.&echo 未找到boot.wim镜像，请把镜像和此脚本放一起。按任意键退出。&pause >nul&exit)
    
54. xcopy boot.wim "C:\PE" /Y /Q >nul 2>&1
    
55. ::复制boot.wim镜像到"C:\PE"文件夹（boot.wim自己准备）
    
56. bcdedit /set {ramdiskoptions} ramdisksdidevice partition=C: >nul 2>&1
    
57. ::设置RAM磁盘镜像所在分区为C:盘（可更改）
    
58. bcdedit /set {ramdiskoptions} ramdisksdipath \PE\boot.sdi >nul 2>&1
    
59. ::设置RAM磁盘SDI路径，可以自定义。
    
60. for /f "delims={,} tokens=2" %%a in ('bcdedit /create /d "PE" -application osloader') do set Guid={%%a}
    
61. ::用bdedit创建启动项，导出GUID序列号，赋值给变量Guid
    
62. bcdedit /set %Guid% device ramdisk="[C:]\PE\boot.wim,{ramdiskoptions}" >nul 2>&1
    
63. ::启动设备（可更改）
    
64. bcdedit /set %Guid% osdevice ramdisk="[C:]\PE\boot.wim,{ramdiskoptions}" >nul 2>&1
    
65. ::系统启动设备（设置和启动设备一样就行，可更改）
    
66. bcdedit /set %Guid% locale zh-CN >nul 2>&1
    
67. ::区域设置中国
    
68. bcdedit /set %Guid% systemroot \windows >nul 2>&1
    
69. ::系统根目录
    
70. bcdedit /set %Guid% detecthal Yes >nul 2>&1
    
71. ::检测HAL（硬件抽象层），如Yes（一般用于PE）
    
72. bcdedit /set %Guid% winpe Yes >nul 2>&1
    
73. ::是否windows PE，如Yes（只有是PE时才需要此参数）
    
74. exit /b

复制代码

jackAqwq

试一试

cqh

学习

孟仁飞

学习

2267981144

多谢辛苦提供分享！

zaolaohu

谢谢分享

ttt0001

这种小工具好象蛮多的，谢谢楼主分享！

gsn0421

感谢分享！

wang1126

谢谢楼主分享

zaolaohu

谢谢分享

in9

谢谢楼主分享！

yc2428

感谢分享

wn168cn@163.com

感谢楼主分享

dna2jm

努力回贴获积分，争取早日在论坛发布自己DIY的PE，以smine发布的PE为基础，修改增加可以用WIN自带的远程桌面远程PE，PE里面固化一些常用的软件

享β亻寸木东

邪恶海盗 发表于 2024-11-7 20:19
感觉像是“把PE添加到启动项”？？？

是滴，是滴，是滴

邪恶海盗

感觉像是“把PE添加到启动项”？？？


二○二四年十一月七日