【20230918】获取离线系统IP地址，兼容PE&桌面系统

BEIKING

1. @echo off
   
2. if /i "%UserName%" == "SYSTEM" (Goto GotAdmin) else (reg query "HKLM\SYSTEM\ControlSet001\Control\MiniNT" 1>nul 2>nul&&Goto GotAdmin)
   
3. :BatchGotAdmin
   
4. Set _Args=%*
   
5. if `%1` neq `` Set "_Args=%_Args:"=""%"
   
6. if exist %WinDir%\System32\fltMC.exe fltMC 1>nul 2>nul||mshta VBScript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c """"%~f0"" %_Args%""",,"runas",1)(Window.Close) 2>nul&&Exit /b
   
7. 
   
8. :GotAdmin
   
9. Pushd "%CD%"&cd /d "%~dp0"
   
10. Title 获取目标系统 IP&Color 2f
    
11. MODE 1>nul 2>nul&&MODE con: Cols=42 Lines=11
    
12. 
    
13. :Start
    
14. setlocal enabledelayedexpansion
    
15. if `%1` neq `` Set Input=%1&Goto Input
    
16. Set n=0&for %%i in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do if exist "%%i:\Windows\System32\Config\SOFTWARE" if exist "%%i:\Windows\System32\Config\SYSTEM" Set /a n+=1&Set dsk!n!=%%i
    
17. if !n! equ 1 Set Input=!dsk%n%!&MODE 1>nul 2>nul&&MODE con: Cols=42 Lines=7&Goto Input
    
18. if !n! geq 2 Set /a l=7+!n!*2&MODE 1>nul 2>nul&&MODE con: Cols=42 Lines=!l!
    
19. Call :EchoX "e0.:选择您要查询的目标系统↓"
    
20. for /l %%i in (1,1,!n!) do echo.&Call :EchoX "            " "9f::[%%i]" "  " "xx.:!dsk%%i!:\Windows"
    
21. echo.&Call :EchoX "70::输入序号[" "74::默认1" "70::]"&Set n=1&Set /p n=:
    
22. Set Input=!dsk%n%!&if not defined Input Set Input=!n!
    
23. 
    
24. :Input
    
25. Set Input=%Input:~0,1%
    
26. if /i "%Input%:" neq "%SystemDrive%" (
    
27.     for %%a in (SOFTWARE SYSTEM) do if not exist "%Input%:\Windows\System32\Config\%%a" Cls&Call :EchoX "cf.:找不到注册表文件！！"&echo "%Input%:\Windows\System32\Config\%%a"&Call :Delay 5 +&Exit
    
28.     reg load HKLM\IP_SOF %Input%:\Windows\System32\Config\SOFTWARE 1>nul 2>nul
    
29.     reg load HKLM\IP_SYS %Input%:\Windows\System32\Config\SYSTEM 1>nul 2>nul
    
30.     Call :GetIPInfo IP_SOF IP_SYS
    
31.     reg unload HKLM\IP_SOF 1>nul 2>nul
    
32.     reg unload HKLM\IP_SYS 1>nul 2>nul
    
33. ) else Call :GetIPInfo SOFTWARE SYSTEM
    
34. if exist "%TEMP%\IPInfo.txt" (msg 1>nul 2>nul&&msg * /time 3600<"%TEMP%\IPInfo.txt"||@start "" "%TEMP%\IPInfo.txt")
    
35. Call :Delay 2 +
    
36. endlocal
    
37. Exit
    
38. 
    
39. :GetIPInfo
    
40. Call :EchoX "e0.:正在查询中，请稍候。。。"
    
41. for /f "tokens=1,2*" %%a in ('reg query "HKLM\%2\select" 2^>nul') do if /i "%%a" == "Default" Set /a x=%%c
    
42. Set "v1=Microsoft\Windows NT\CurrentVersion\NetworkCards"
    
43. Set "v2=ControlSet00%x%\Control\Network"
    
44. Set "v3=ControlSet00%x%\services\Tcpip\Parameters"
    
45. Set "s=EnableDHCP NameServer IPAddress SubnetMask DefaultGateway"
    
46. Set "s=%s% DHCPNameServer DHCPIPAddress DHCPSubnetMask DHCPDefaultGateway"
    
47. Set n=&for /f "delims=" %%a in ('reg query "HKLM\%1\%v1%" 2^>nul') do (
    
48.     Set "v=%%a"
    
49.     if "!v:%v1%\=!" neq "!v!" (
    
50.         Set /a n+=1
    
51.         for /f "tokens=1,2*" %%b in ('reg query "%%a" 2^>nul') do if /i "%%b" == "ServiceName" (Set "Guid!n!=%%d") else if /i "%%b" == "Description" Set "NetCard!n!=%%d"
    
52.     )
    
53. )
    
54. if not defined n Call :EchoX "cf.:找不到网卡！！"&Call :Delay 5 +&Exit
    
55. (for /f "tokens=1,2*" %%a in ('reg query "HKLM\%2\%v3%" 2^>nul') do (
    
56.     if /i "%%a" == "Domain" (
    
57.         if "%%c" neq "" (echo 域名名称：%%c) else echo 域名名称：
    
58.     ) else if /i "%%a" == "HostName" echo 主机名称：%%c
    
59. )) >"%TEMP%\IPInfo.txt"
    
60. for %%a in (%s%) do Set "_%%a=1"
    
61. (for /l %%a in (1 1 %n%) do (
    
62.     echo.&echo 网卡名称：!NetCard%%a!
    
63.     for %%b in (%s%) do Set "%%b="
    
64.     Set flag=&for /f "delims=" %%b in ('reg query "HKLM\%2\%v2%" /s 2^>nul') do (
    
65.         if defined flag (
    
66.             for /f "tokens=1,2*" %%c in ("%%b") do if /i "%%c" == "Name" echo 连接名称：%%e& Set "flag="
    
67.         ) else (
    
68.             Set "v=%%b"
    
69.             for %%c in ("\!Guid%%a!") do if "!v:%%~c=!" neq "!v!" Set flag=1
    
70.         )
    
71.     )
    
72.     for /f "tokens=1,2*" %%b in ('reg query "HKLM\%2\%v3%\Interfaces\!Guid%%a!" 2^>nul') do if defined _%%b if "%%d" neq "" Set "v=%%d"&Set "%%b=!v:\0=        !"
    
73.     if defined IPAddress (echo ＩＰ地址：!IPAddress!) else echo ＩＰ地址：!DHCPIPAddress!        [自动获取]
    
74.     if defined SubnetMask (echo 子网掩码：!SubnetMask!) else echo 子网掩码：!DHCPSubnetMask!
    
75.     if defined DefaultGateway (echo 默认网关：!DefaultGateway!) else echo 默认网关：!DHCPDefaultGateway!
    
76.     if defined NameServer (Set DNS=!NameServer: =,!&Set dhcp=) else (Set DNS=!DHCPNameServer: =,!&Set dhcp=        [自动获取])
    
77.     Set d=DNS 地址：&for %%i in (!DNS!) do if not defined "n%%a_%%i" echo !d!%%i!dhcp!&Set ""n%%a_%%i"=%%a"&Set dhcp=&Set d=　　　　　
    
78. )) >>"%TEMP%\IPInfo.txt"
    
79. Goto :eof
    
80. 
    
81. :Delay :: 延迟操作 <%1=Sec|延迟秒数> [%2=+|显示倒计时]。
    
82. if `%2` == `+` (Set n=2) else Set n=1
    
83. if exist %WinDir%\System32\timeout.exe (timeout /t %1 %n%>nul) else if exist %WinDir%\System32\choice.exe (choice /t %1 /d y /n >nul) else ping 127.1 -n %1 >nul
    
84. Goto :eof
    
85. 
    
86. :EchoX :: 显示彩色文字 (不支持半角字符 \ / : * ? " < >|. % ! ~)。
    
87. setlocal enabledelayedexpansion
    
88. Set echox=EchoX.exe&&!echox! 1>nul 2>nul||(Set echox=&mkdir "%TEMP%\EchoX" 2>nul)
    
89. for %%a in (%*) do (
    
90.     Set "param=%%a"&Set "param=!param:"=!"
    
91.     Set "color=!param:~0,2!"&(if not exist %WinDir%\System32\findstr.exe if not defined echox Set "color=xx")
    
92.     Set n=0&(if "!param:~2,2!" == "::" Set n=1)&(if "!param:~2,2!" == ".:" Set n=2)
    
93.     if !n! gtr 0 (
    
94.         if /i "!color!" == "xx" (Set /p="_!param:~4!"<nul) else (Set param=%%~nxa&if defined echox (!echox! -c !color! -n "!param:~4!") else (Pushd "%TEMP%\EchoX" 2>nul&>"!param:~4!",Set /p= <nul&findstr /a:!color! .* "!param:~4!*"&del "!param:~4!"&Popd))
    
95.         if !n! == 2 echo.
    
96.     ) else if defined param Set /p="_!param!"<nul
    
97. )
    
98. endlocal
    
99. Goto :eof

复制代码

批处理脚本用途：
获取(离线和在线)Win系统主机：域名名称、主机名称、网卡信息（连接名称、IP地址、子网掩码、默认网关、DNS地址）

读取离线注册表IP信息方法非原创，借鉴的是无忧某位坛友分享的。
允许传参调用：   
    获取目标系统IP.bat C
    获取目标系统IP.bat D

【20230916】
1）释放临时文件到%TEMP%目录，避免因当前目录无写权限而报错。
2）格式化DNS地址输出并去重。

【20230918】
1）优化多系统选择体验，单一系统自动打开查询，多系统提供列表选择
2）支持网卡多IP设置查询

链接: https://pan.baidu.com/s/1tVJv4NWAY9bkzIy6VSHX_w 提取码: sad4

2012yjkiw

大佬脚本不错，能不能出个不输出弹出对话框的，而是输出到D:\IpSet.bat；并且这个批处理可以直接运行即可设置IP？万谢！

wn168cn@163.com

感谢楼主分享

lxptyc

这是个好东西

hehuiying

谢谢分享

Anson4

感谢分享！

ljmmjl

谢谢分享

你好一起玩

这个绝对好的,收藏了.做维护很有用

xcj138

谢谢分享

kuding

这个好强大。。。建议加版本号或更新时间

无犹启动

谢谢分享

蛮牛士

6666666

zguest

收藏，很实用的工具

xtjuf

这个还是很有用的，感谢分享

方长

看起来很不错哦，收藏之~~~
谢谢LZ啦！！！

666666

这个批处理好用啊，找IP省事多了。

casttt

感谢分享,有忘记时的后备

x1aox1n

感谢分享，谢谢了

yzicee

离线获取IP经常要用到，谢谢分享

hi9808

感谢分享~~很不错的工具收藏了

sun4008

感谢楼主，很好用！

2010zihan

收藏备用！

promrhxq

感谢分享好东东

呵呵#1861

谢谢分享

yingmeng

感谢分享

BEIKING

holley2008 发表于 2023-9-18 14:15
我直接在服务器桌面运行的脚本，见图：

【20230918】
1）优化多系统选择体验，单一系统自动打开查询，多系统提供列表选择
2）支持网卡多IP设置查询

BEIKING

holley2008 发表于 2023-9-18 14:15
我直接在服务器桌面运行的脚本，见图：

明白了，，我等会儿会更新。

2939788244

谢谢分享

holley2008

BEIKING 发表于 2023-9-18 13:36
你是什么系统环境，PE还是正常系统。
系统版本说下，还有你是记事本打开显示，还是窗口显示

我直接在服务器桌面运行的脚本，见图：

BEIKING

holley2008 发表于 2023-9-18 12:03
我获取的结果是这样？

你是什么系统环境，PE还是正常系统。
系统版本说下，还有你是记事本打开显示，还是窗口显示