傻瓜式U盘NTLDR+GRLDR启动盘制作批处理

wowfans

很简单的
附件在770K左右(因里面还有精简了目录的PELDR和NTDETECT.COM等PE文件)
传到某兄弟的网盘里面去了

http://shing.ys168.com

批处理内容预览

@echo off
echo 继续操作之前, 请确保下列事项已经完成：
echo.
echo 1. U盘/移动硬盘已经插入, 并且已经备份了即将做启动盘的分区内的数据
echo 2. 如果你的U盘/移动硬盘想做启动盘的分区文件系统是NTFS, 请先将其格式化成FAT32/FAT均可
echo.
echo.
echo 即将进入的下一步, 会弹出HP USB FORMAT TOOL, 在其界面中, 文件系统选择FAT/FAT32, 选中“创建一个MSDOS启动盘”
echo 按任意键进入下一步
pause>nul
cls
color 0c
echo HP USB Disk Storage Format Tool已经启动
echo.
echo.
echo 你只需要对这3处进行改动
echo.
echo  1.Device下拉列表中, 选择你的U盘或者移动硬盘
echo  2.“file system”下拉列表中, 选fat或者fat32
echo  3.选中“Creat a DOS startup disk”
echo.
echo 其他选项按默认值不要动, 然后单击“start”按钮
echo.
echo 现在批处理处于等待状态, 当格式化完毕之后, 关闭HP USB Disk Storage Format Tool, 批处理会自动继续执行
echo.
HPUSB.EXE
cls
color 0a
echo 处理中...
echo 判断U盘盘符
set upan=
for %%i in (c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z) do (
if exist %%i:\GAOZQ.UDD SET UPAN=%%i:&goto upanok
)
goto upanfail
:upanok
echo 自动判断U盘盘符为%upan%
echo.
echo 删除U盘的DOS启动文件
attrib %upan%\io.sys -h -s -r
del %upan%\io.sys
attrib %upan%\command.com -h -s -r
del %upan%\command.com
attrib %upan%\gaozq.udd -h -s -r
del %upan%\gaozq.udd
:btsect
echo.
echo 调用bootsect进行bootmgr引导处理
bootsect.exe /nt60 %upan%|find "unreliable" >nul
if errorlevel 1 goto btsectok
echo.
echo.
echo.
echo BOOTSECT报告启动扇区写入不可靠啦...
echo 请专心点, 不要干别的！
echo 可能原因为：U盘正在被别的程序所使用, 例如兄弟(or姐妹)你一心两用, 在U盘上创建了文件, 并打开/运行了该文件之类的, 关闭打开的文件后程序按任意键程序将重新尝试写入引导
pause >nul
goto btsect
:btsectok
echo.
echo 成功为U盘写入vista的引导记录
echo 本U盘的启动形式为NTLDR+GRLDR多重启动, 其中NTLDR已经改名为BOOTMGR, 因个人觉得vista的启动扇区兼容性好于NT的启动扇区
echo.
echo 即将开始文件复制操作
XCOPY /E /H /K USBROOT %upan%\
echo.
echo 文件复制完毕
echo U盘启动制作完成,将打开u盘的boot目录, 请自己添加启动项
echo 启动菜单在%upan%\boot\grub\menu.usb中, 请自己编辑以添加
echo 按任意键打开boot目录等并退出....
pause >nul
start explorer %upan%\boot
start notepad %upan%\boot\grub\menu.usb
start notepad %upan%\boot\使用说明.txt
exit
:upanfail
echo 系统没有检测到你的U盘, 程序即将推出
pause
exit

hwd6

很好，谢谢楼主，复制下来试试

wowfans

复制下来没用的.
压缩包里面很多相关文件的
得把整个压缩包下载下载再运行
貌似标题不太恰当,应该说.....模板之类的

wowfans

文件稍微改了一点点
先前的boot\x.x文件前后不对应
因为我硬盘上有grldr
所以就改了,不然还会从硬盘的grldr来启动的
grldr改名成usbgr
一时疏忽
x.x配置文件应为
[boot loader]
timeout=5
default=c:\usbgr
[operating systems]
c:\usbgr="USB GRLDR"


先前的版本为default=c:\grldr
20:53以前下载的同志手动修改下这个文件就可以了
就这么几个字符...

2011pkri

楼主！网盘失效了，能不能再发一个啊！万分感谢！