【20111226更新相对完美版】写了个删除空文件夹的bat

hb_711

写的并不怎么好！请高手指点！xp下通过rdwin7下我不了解！小心把你的正常文件夹也删除了！


刚才无聊，重写了一个！！！相对完美！！！
【请下载5楼的附件】
1，支持畸形文件夹
2，如果子目录删除成功自动试删除上级目录
3，文件列表有序号
4，有用时显示

[ 本帖最后由 hb_711 于 2011-12-31 16:31 编辑 ]

pznpt

感谢楼主分享，代码稍作简化，请高手指点。

@echo off
echo 正在查找并删除本机空文件夹，请稍候...
setlocal enabledelayedexpansion
if exist !temp!\lb del !temp!\lb>nul
set n=0
for %%i in (c d e f g h i j k l m n o p q r s t u v w x y z) do (
for /f "delims=" %%a in ('dir /ad /b /s %%i:\ ^|sort /r') do (
rd "%%a"&&set/a n+=1&&echo %%a>>!temp!\lb
)) 1>nul 2>nul
echo.
if not exist !temp!\lb echo 你的电脑没有空文件夹!&goto quit
echo 本次删除!n!个空文件夹,你想查看吗？
echo.
echo          查看………………1
echo.
echo          退出………………2
echo.&set/p xz=请选择：
if !xz! == 1 notepad.exe !temp!\lb
if !xz! == 2 exit
:quit
echo.&echo 按任意键退出&pause>nul

XP、Win7下测试可行

[ 本帖最后由 pznpt 于 2011-12-25 21:13 编辑 ]

renchmin

这个不错的支持楼主了啊。

candyil

不错。。。。。顶一下。。

hb_711

我重写了个！有几处代码参考了2楼pznpt的！谢谢！只是一时无聊！瞎搞！高手勿笑！
一楼的wm.zip里边少写了一个“\”请下载这里的！手机上网，一楼的附件难删！

[ 本帖最后由 hb_711 于 2011-12-26 20:50 编辑 ]

hb_711

@echo off
echo.
echo 正在扫描和删除本机空文件夹请稍侯……
set /a ks=%time:~0,2%*3600+%time:~3,2%*60+%time:~6,2%
if exist %temp%\lb del %temp%\lb 1>nul 2>nul
setlocal EnableDelayedExpansion
set sz=0
for %%a in (q w e r t y u i o p s d f g h j k l z x c v n m) do (
if exist %%a:\nul (
for /f "delims=" %%i in ('dir /ad /s /b %%a:\') do (
rd "%%i\" &&set /a sz+=1 &&echo !sz! %%i >>%temp%\lb &&rd "%%~pi\" &&set /a sz+=1 &&echo !sz! %%~dpi >>%temp%\lb||rd "%%i.\" &&set /a sz+=1 &&echo !sz! %%i>>%temp%\lb
)1>>nul 2>>nul
)
)
if not exist %temp%\lb goto my
set /a sj=%time:~0,2%*3600+%time:~3,2%*60+%time:~6,2%-ks
cls
echo.
echo 本次删除%sz%个空文件夹！用时%sj%秒！你想查看吗？
echo.
echo.
echo.
echo              查看………………1
echo.
echo              退出………………2
echo.
set /p xz=请选择：
if %xz% == 1 goto ck
if %xz% == 2 goto tc
del %temp%\lb 1>nul 2>nul
exit
:ck
cls
echo.
echo.
echo 你删除了下列文件夹：
echo.
start notepad.exe %temp%\lb
exit
:tc
del %temp%\lb 1>nul 2>nul
exit
:my
cls
echo.
echo 你的电脑没有空文件夹！
echo.
echo 按任意键退出!
pause>nul

joy7501

支持一下，2011年最后一贴