批处理显示九宫格

namejm

　　发一个小玩意出来耍耍：

1. 
   
2. @echo off
   
3. 
   
4. :: 九宫格的含义：
   
5. :: 戴九履一，左三右七，二四为肩，六八为足。
   
6. :: 换而言之，就是把1～9排成三行三列，横竖斜三个数相加都等于15
   
7. :: 首发于：http://www.cn-dos.net/forum/viewthread.php?tid=26647
   
8. 
   
9. title 九宫格
   
10. mode con cols=40 lines=20
    
11. set n1=0
    
12. setlocal enabledelayedexpansion
    
13. 
    
14. :begin
    
15. cls
    
16. set n5=5
    
17. set str= 1 2 3 4 6 7 8 9
    
18. set /a n1+=1
    
19. if %n1% gtr 9 exit
    
20. call :intercept %n1%
    
21. set /a n9=15-%n1%-%n5%
    
22. call :intercept %n9%
    
23. for %%i in (%str%) do (
    
24.     set flag=
    
25.     set n2=%%i
    
26.     set str_tmp=%str%
    
27.     call :intercept !n2!
    
28.     set /a n8=15-!n2!-!n5!
    
29.     set /a n3=15-!n1!-!n2!
    
30.     set /a n7=15-!n8!-!n9!
    
31.     set /a n4=15-!n1!-!n7!
    
32.     set /a n6=15-!n3!-!n9!
    
33.     for %%j in (!n3! !n4! !n6! !n7! !n8!) do call :intercept %%j
    
34.     if not "!str!"=="" set flag=1
    
35.     set /a sum1=!n3!+!n5!+!n7!
    
36.     set /a sum2=!n4!+!n5!+!n6!
    
37.     if !sum1! equ 15 if !sum1! equ !sum2! if not defined flag call :result
    
38.     set str=!str_tmp!
    
39. )
    
40. goto begin
    
41. 
    
42. :intercept
    
43. set str=!str: %1=!
    
44. goto :eof
    
45. 
    
46. :result
    
47. cls
    
48. echo.
    
49. echo.
    
50. echo.
    
51. echo            ┌──┬──┬──┐
    
52. echo            │ %n1%  │ %n2%  │ %n3%  │
    
53. echo            ├──┼──┼──┤
    
54. echo            │ %n4%  │ %n5%  │ %n6%  │
    
55. echo            ├──┼──┼──┤
    
56. echo            │ %n7%  │ %n8%  │ %n9%  │
    
57. echo            └──┴──┴──┘
    
58. echo.
    
59. echo ________________________________________
    
60. echo.
    
61. echo             按任意键显示下一个
    
62. pause>nul
    
63. goto :eof
    

复制代码

spiegboy

能给个详细的解释么，谢谢

namejm

　　九宫格代码思路如下：

　　既然要求横竖斜三个数字相加都要等于15，则中心位置上的数字只能是3个数字的算术平均值5；然后按照1～9的顺序依次给第1格的变量赋值，则第9格的数值将随着第一格的数值而变化，换而言之，只要第1格的数值确定了，则第9格的数值也就确定了；第1、5、9格的数值确定之后，再把剩余数值中的任意一个赋给第2格的变量，则第8格的数值也就确定了；第1、2、5、8、9格的数值确定之后，按照横竖斜的和都为15的规律，则所有格子里的数值也就确定了，剩余的工作就是检测每个格子的数值是否重复、横竖斜的和是否为15。当所有的条件都符合之后，就显示结果，等待下一次变化。