求助关于pe安装代码的问题

HB天意

我修改的pe始终无法安装到硬盘上。
好像是winpe.iso无法复制到C盘。

我提取了无声无息pe中的代码。但是他的内核是img的，我把代码修改成了iso。
就是出问题。大家帮我看看是怎么回事。

@Echo Off
mode con cols=65 lines=26
Set Prog=维护PE安装工具
Set L1=　　　　　　╭──────────────────╮
Set L2=　　　　　　│　　　　　　　　　　　　　　　　　　│
Set L3=　　　╭──┤　       PE维护光盘安装工具      　 ├──╮
Set L4=　　　│　　│　　　　　　　　　　　　　　　　　　│　　│
Set L5=　　　│　　╰──────────────────╯　　│
Set L6=　　　│　　　　　　　　　　　　　　　　　　　　　　　　│
Set L7=　　　├────────────────────────┤
Set L8=　　　│　                 欢迎使用                   　│
Set L9=　　　╰────────────────────────╯
Title %Prog%
::初始化一些变量
Set PEFile=WINPE.IS_
Set SOFT=外置程序
Set PEIni=%SOFT%\WinPE.INI
Set LogFile=PEInstall.log
Set AddATTR=ATTRIB +S +H +R
Set DelATTR=ATTRIB -S -H -R
::核心文件=%PEFile%；外置程序位置=%SOFT%；外置配置文件=%PEIni%；日志文件名称=%LogFile%；
:CheckOS
if /i not "%os%."=="Windows_NT." goto SystemErro
::判断系统版本并设置TheOS
ver|find /i " 6.0">nul &&set Winver=vista&&  set TheOS=Vista
ver|find /i " 5.0">nul &&set Winver=winnt&&  set TheOS=2000
ver|find /i " 5.1">nul &&set Winver=winnt&&  set TheOS=XP
ver|find /i " 5.2">nul &&set Winver=winnt&&  set TheOS=2003
goto Start
:SystemErro
cls
Echo.
Echo.
Echo  注意：未经测试，本软件可能不适用于非 Windows PE/2000/XP/2003/Vista 操作系统。
Echo  按回车键退出安装程序
Pause >nul
Exit
::初始化完毕，开始加载界面
:Start
CLS
Title %Prog%——安装
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo 　　　│ 　请选择安装方式：　　　　　　　　　　　　　　 │
Echo %L6%
Echo 　　　│　　[1] 普通安装/启动 (硬盘安装)　　　　　　　　│
Echo 　　　│　　[2] 安装至U 盘(安装到移动硬盘有风险）       │
Echo 　　　│　　[Q] 退出安装　　　　　　　　　　　　　　　　│
Echo %L6%
Echo %L7%
Echo %L7%
Echo %L8%
Echo %L9%
Echo.
Echo　　　    您现在使用的是 Windows %TheOS% 操作系统 ！
if "%TheOS%"=="XP" Echo　　　    ( 或 Windows XP 核心的 WinPE )
if "%TheOS%"=="2003" Echo　　　    ( 或 Windows 2003 核心的 WinPE )
if "%TheOS%"=="Vista" Echo　　　    ( 请确保您拥有管理员权限以及关闭了UAC，否则安装可能失败 )
Echo.
Set Choice=
Set /P Choice=　　　请选择要进行的操作 (1/2/Q) ，按回车确认：
If "%Choice%"=="" Goto Start
If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
If /I "%Choice%"=="1" Goto HD
If /I "%Choice%"=="2" Goto UD
If /I "%Choice%"=="Q" Exit
Goto Start
:HD
Set RP=
For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BOOT.INI Set RP=%%I:
::设定PE安装文件夹的名称
Set PEDIR=%RP%\WINPEXP
::设定完毕
Set TargetP=硬盘&&Set TxtSp=
::判断是否安装了PE
If Exist %PEDIR% Goto Err1
FIND /I "%PEDIR%" %RP%\BOOT.INI>NUL 2>NUL
If "%Errorlevel%"=="0" Goto Err1
::选择不同的安装模式
If /i "%TheOS%"=="Vista" (
       goto :Vista_Install
) Else (
       goto :Pubilc_Install
)
Goto :HD
:UD
CLS
Title %Prog%——U 盘安装
For /F "skip=2 tokens=*" %%I In ('MYINS\CHECKUSB.EXE') DO SET Us=%%I
::这里的%Us%是U盘的盘符
If "%Us%"=="当前可移动磁盘分区：" Goto NoUD
Echo %Us%&&Echo.
If "%NoUD%"=="Yes" Echo 错误：您设定的分区 %RP% 不存在、写保护、未格式化或不是 U 盘分区，请按任意键重新设定。&&Echo.
Set /P RP=请选择您的 U 盘盘符（不需要冒号，例如 F）：
Echo.&&Echo.
If "%RP%"=="" Goto UD
If Not "%RP%"=="" Set RP=%RP:~0,1%:
SET UU=%RP%
For /F %%I In ('MYINS\CHECKUSB.EXE %RP%') DO SET Err2=%%I
If Not "%Err2%"=="1" Set NoUD=Yes&&Goto UD
::上面这里测试了输入的U盘盘符是否存在或不是U盘分区或（未格式化）::未格式化这里不知道能不能检测出来，估计是下面的代码的工作，
Set TestFile=%RP%\MiniPETest_%RANDOM%.MT
Cd.>%TestFile%
If Not Exist %TestFile% Set NoUD=Yes&&Goto UD
Del %TestFile% /Q>NUL 2>NUL
::上面这里测试了U盘是否写保护或未格式化
Set U=U&&Set PEDIR=%RP%\WINPEXP
Set TargetP= U 盘&&Set TxtSp=
::那个Set U=U用来干什么的？
CLS
Echo 您选择的 U 盘分区为 %RP%，下面将对您的 U 盘进行格式化并写入引导
Echo 注意！:如果您选择的是硬盘硬盘，那么格式化的不是一个分区，而是整个移动硬盘。
ECHO.
Echo 请严格按照相关工具软件界面中的提示操作，以防出错。
Echo.
Echo 请在根目录SETUP下选择DOS基本文件。
Echo 使用格式化工具时，请勿勾选快速格式化，按任意键开始.......
PAUSE>NUL
start /wait MYINS\HPUSBFW.EXE
cls
Echo 正在复制文件请稍候....
echo.
%DelATTR% %RP%\COMMAND.COM&&Del %RP%\COMMAND.COM >NUL 2>NUL
%DelATTR% %RP%\IO.SYS&&Del %RP%\IO.SYS >NUL 2>NUL
If Not Exist %PEDIR% MD %PEDIR%
Copy ..\%PEFile% %PEDIR% /Y>NUL 2>NUL
XCOPY ..\%SOFT% /E %RP%\%SOFT%\ /Y /H /R>NUL 2>NUL
XCOPY BOOT /E %RP%\boot\ /Y /H /R>NUL 2>NUL
Copy MYINS\IO.SYS %RP%\ /y>NUL 2>NUL
%AddATTR% %RP%\IO.SYS /S /D
%AddATTR% %RP%\%SOFT% /S /D
%AddATTR% %PEDIR% /S /D
%AddATTR% %RP%\boot /S /D
Goto SUCCESS
:NoUD
CLS
Title %Prog%——U 盘安装
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo 　　　│ 您的计算机似乎没有安装 U 盘，您想怎么办？　　　│
Echo %L6%
Echo 　　　│　　 返回首页，重新选择安装选项。　　　　　　│
Echo 　　　│　　[Q] 退出安装　　　　　　　　　　　　　　　　│
Echo %L6%
Echo %L7%
Echo %L8%
Echo %L9%
Echo.
Set Choice=
Set /P Choice=　　　请选择要进行的操作 (B/Q) ，然后按回车：
If "%Choice%"=="" Goto NoUD
If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
If /I "%Choice%"=="B" Goto Start
If /I "%Choice%"=="Q" Exit
Goto NoUD
Exit
:Err1
CLS
Title %Prog%——卸载
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo %L4%
Echo %L5%
Echo %L6%
Echo 　　　│ 您的%TargetP%中好像已经安装了 WinPE，您想怎么办？%TxtSp%　│
Echo %L6%
Echo 　　　│　　[1] 卸载原有的 WinPE，并且重新安装。　　　　│
Echo 　　　│　　[2] 卸载原有的 WinPE，并且不再安装。　　　　│
Echo 　　　│　　 返回首页，重新选择安装选项。　　　　　　│
Echo 　　　│　　[Q] 退出安装　　　　　　　　　　　　　　　　│
Echo %L6%
Echo %L7%
Echo %L8%
Echo %L9%
Echo.
Set Choice=
Set /P Choice=　　　请选择要进行的操作 (1/2/B/Q) ，然后按回车：
If "%TargetP%"=="硬盘" Set U=
If "%Choice%"=="" Goto Err1
If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
If /I "%Choice%"=="1" Set Choi=1&&Goto UnInstall
If /I "%Choice%"=="2" Goto UnInstall
If /I "%Choice%"=="B" Goto Start
If /I "%Choice%"=="Q" Exit
Goto Err1
Exit
:UnInstall
If Exist %RP%\%LogFile% For /F "eol=; tokens=2 delims=^=" %%i In ('find /I ^"WinPE外挂位置^" %RP%\%LogFile%') do SET OPD=%%i
If Not "%U%"=="" Set OPD=%RP%
If Exist %RP%\%LogFile% %DelATTR% %RP%\%LogFile%&&Del %RP%\%LogFile% /Q>NUL 2>NUL
If Exist %RP%\PELDR %DelATTR% %RP%\PELDR&&Del %RP%\PELDR /Q>NUL 2>NUL
If Exist %PEDIR% RD %PEDIR% /S /Q>NUL 2>NUL
If Exist %RP%\boot\GRUB\grub RD %RP%\boot /S /Q>NUL 2>NUL
If Exist %OPD%\%SOFT% RD %OPD%\%SOFT% /S /Q>NUL 2>NUL
If Exist %UU%\IO.SYS %DelATTR% %UU%\IO.SYS&&Del %UU%\IO.SYS /Q>NUL 2>NUL
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE&&Del %RP%\WINNT.XPE /Q>NUL 2>NUL
If /i "%TheOS%"=="Vista" If Exist %RP%\NTDETECT.COM %DelATTR% %RP%\NTDETECT.COM&&Del %RP%\NTDETECT.COM /Q>NUL 2>NUL
If /i "%TheOS%"=="Vista" If Exist %RP%\BOOTFONT.BIN %DelATTR% %RP%\BOOTFONT.BIN&&Del %RP%\BOOTFONT.BIN /Q>NUL 2>NUL
::针对VISTA下是否多系统的判断卸载
If NOT Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.INI&&Del %RP%\BOOT.INI
%DelATTR% %RP%\BOOT.INI>NUL 2>NUL
If Exist %RP%\BOOT.BAK (
%DelATTR% %RP%\BOOT.BAK
TYPE %RP%\BOOT.BAK|FIND /I /V "%PEDIR%">%RP%\BOOT.INI
) Else (
If Exist %RP%\BOOT.INI Copy %RP%\BOOT.INI %RP%\BOOT.BAK /Y>NUL 2>NUL
If Exist %RP%\BOOT.BAK TYPE %RP%\BOOT.BAK|FIND /I /V "%PEDIR%">%RP%\BOOT.INI
)
If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK&&Del %RP%\BOOT.BAK>NUL 2>NUL
If Exist %RP%\BOOT.INI %AddATTR% %RP%\BOOT.INI >NUL 2>NUL
Set RP=
Title %Prog%——卸载完成
If "%Choi%"=="1" (Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键准备安装 。。。&&PAUSE>NUL 2>NUL&&Goto Start)
Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键退出 。。。
PAUSE>NUL 2>NUL
Exit
:Vista_Install
For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BOOTMGR Set RP=%%I:
Set PEDIR=%RP%\WINPEXP
set gname=WinPE MINI SYSTEM
set gname2=WINPEXP\AVLDR
If Exist %PEDIR% Goto Err1
If "%OP%"=="" Call :SetExtra
Set TargetP=硬盘 && Set TxtSp=
If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
Echo 正在复制文件，请稍候 ............
COPY MYINS\PELDR %RP%\PELDR >Nul 2>Nul
COPY MYINS\AVLDR %PEDIR%\AVLDR >Nul 2>Nul
COPY MYINS\WINNT.XPE %RP%\WINNT.XPE >Nul 2>Nul
COPY MYINS\NTDETECT.COM %RP%\NTDETECT.COM >Nul 2>Nul
COPY ..\BOOTFONT.BIN %RP%\BOOTFONT.BIN
%AddATTR% %RP%\BOOTFONT.BIN
%AddATTR% %RP%\NTDETECT.COM /S /D
Call :CopyAndSetFiles
Goto SUCCESS
:Pubilc_Install
Title %Prog%——普通安装
If "%OP%"=="" Call :SetExtra
If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
Echo 正在复制文件，请稍候 ............
::拷贝必要的引导文件
COPY MYINS\AVLDR %PEDIR%\AVLDR >Nul 2>Nul
COPY MYINS\PELDR %RP%\PELDR >Nul 2>Nul
COPY MYINS\WINNT.XPE %RP%\WINNT.XPE >Nul 2>Nul
Call :CopyAndSetFiles
Goto SUCCESS
:CopyAndSetFiles
::拷贝PE的核心
Copy ..\%PEFile% %PEDIR% /Y>NUL 2>NUL
::拷贝外置程序
IF NOT "%OP%"=="" XCOPY ..\%SOFT% /E %OP%\%SOFT%\ /Y /H /R>NUL 2>NUL
::修改启动菜单
If "%U%"=="" If Exist %RP%\BOOT.INI %DelATTR% %RP%\BOOT.INI
If "%U%"=="" If Exist %RP%\BOOT.INI If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK
If "%U%"=="" If Exist %RP%\BOOT.INI Copy %RP%\BOOT.INI %RP%\BOOT.BAK>NUL 2>NUL
If "%U%"=="" If Exist %RP%\BOOT.INI TYPE %RP%\BOOT.BAK|FIND /I /V "%RP%\WINPEXP">%RP%\BOOT.INI
If "%U%"=="" If Exist %RP%\BOOT.INI Echo %RP%\WINPEXP\AVLDR="WinPE MINI SYSTEM">>%RP%\BOOT.INI
if /i "%TheOS%"=="Vista" If NOT Exist %RP%\BOOT.INI CALL :BOOT
::添加属性
IF NOT "%OP%"=="" %AddATTR% %OP%\%SOFT% /S /D
If Exist %RP%\BOOT.INI %AddATTR% %RP%\BOOT.INI /S /D
If Exist %RP%\PELDR %AddATTR% %RP%\PELDR /S /D
%AddATTR% %PEDIR% /S /D
::添加日志方便卸载
If "%U%"=="" Call :添加日志
Goto :EOF

:SUCCESS
If "%U%"=="" IF NOT EXIST %RP%\BOOT.INI GOTO SETUPErr
Title %Prog%——安装完成
CLS
For %%i In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do If /I "%RP%"=="%%i:" Set RP=%%i:
Echo 已经成功将镜像 %PEFile% 安装到您的 %RP% 盘。
If "%U%"=="" (
Echo 外置程序 文件夹按照您的设置，复制到了 %OP% 盘。
Echo.
If Exist %RP%\Boot.INI Echo 系统分区中的 BOOT.INI 备份为 BOOT.BAK,多系统同上。
)
Echo.&&Echo.
Echo 如果您需要将 WinPE 卸载，请重新运行本安装程序。
Echo.
Echo 请按任意键退出......
PAUSE>NUL 2>NUL
Exit
:SetExtra
CLS
If "%NoOP%"=="Yes" Echo 错误：您设定的分区不存在或写保护，请按任意键重新设定。&&Echo.
Set /P OP=请设定 外置程序 存放的分区符[不需要冒号，例如 D(推荐)]：
Echo.&&Echo.
If "%OP%"=="" Goto SetExtra
If Not "%OP%"=="" Set OP=%OP:~0,1%:
Set TestFile=%OP%\MaotaoTest.MT
Cd.>%TestFile%
If Not Exist %TestFile% Set NoOP=Yes&&Goto SetExtra
Del %TestFile% /Q>NUL 2>NUL
Goto :EOF
:添加日志
>%RP%\%LogFile% Cd.
>>%RP%\%LogFile% Echo ;此文件为 WinPE 的安装LogFile，请不要随意删除
>>%RP%\%LogFile% Echo ;否则可能会造成 WinPE 的卸载不够彻底！！！
>>%RP%\%LogFile% Echo.
>>%RP%\%LogFile% Echo WinPE镜像文件=%PEFile%
>>%RP%\%LogFile% Echo WinPE外挂位置=%OP%
>>%RP%\%LogFile% Echo WinPE安装日期=%Date% %Time%
%AddATTR% %RP%\%LogFile%
Goto :EOF
:BOOT
ECHO [boot loader]>>%RP%\BOOT.INI
ECHO [operating systems]>>%RP%\BOOT.INI
ECHO %RP%\%gname2%="%gname%">>%RP%\BOOT.INI
goto :eof
:SETUPErr
echo 安装到硬盘可能失败。请检查%RP%上的BOOT.INI文件中是否有PE的启动项，按任意键退出..........
pause >nul

红色是我修改的。其他没有变。

[ 本帖最后由 yidawpf 于 2008-9-17 15:33 编辑 ]

HB天意

附下我的pe布局图。外置程序是直接加载的。不是wim模式。

421062724

刚开学，还没买电脑，没办法，暂时帮不到你

HB天意

我的就是在你这提取的。
我也不知道怎么回事。应该是可以安装的，但就是出问题。

liuyw001

我也想知道！

[ 本帖最后由 liuyw001 于 2008-9-17 21:16 编辑 ]

HB天意

刚才不是发了个代码吗？也有问题？

421062724

出问题？具体错误提示是？你发出来，我明天去学校机房帮你看看

421062724

WINNT.XPE里的参树看清楚，～～～也就是这句COPY MYINS\WINNT.XPE %RP%\WINNT.XPE >Nul 2>Nul
看看MYINS\WINNT.XPE 这里的参数改了没有

HB天意

原帖由 421062724 于 2008-9-18 07:45 发表
WINNT.XPE里的参树看清楚，～～～也就是这句COPY MYINS\WINNT.XPE %RP%\WINNT.XPE >Nul 2>Nul
看看MYINS\WINNT.XPE 这里的参数改了没有

我的winnt.xpe参数和你的不一样。

我的问题是winpe.is_文件不能拷贝到C盘。就是这个问题。

421062724

::拷贝PE的核心
Copy ..\%PEFile% %PEDIR% /Y>NUL 2>NUL
~~~~这里有拷贝命令～～～但是却不能拷贝？？～～ＲＰ问题了？

HB天意

我 就改了红色的地方，其他的没有改啊真是奇怪啊。

421062724

确实很奇怪～看来是RP问题

HB天意

那怎么解决呢？
我一直都没有搞定啊。

mapeimapei

试试XCOPY命令，，这个命令比copy强大些。。


C:\>xcopy /?
复制文件和目录树。
XCOPY source [destination] [/A | /M] [/D[:date]] [/P] [/S [/E]] [/V] [/W]
                           [/C] [/I] [/Q] [/F] [/L] [/G] [/H] [/R] [/T] [
                           [/K] [/N] [/O] [/X] [/Y] [/-Y] [/Z]
                           [/EXCLUDE:file1[+file2][+file3]...]
  source       指定要复制的文件。
  destination  指定新文件的位置和/或名称。
  /A           只复制有存档属性集的文件，
               但不改变属性。
  /M           只复制有存档属性集的文件，
               并关闭存档属性。
  /D:m-d-y     复制在指定日期或指定日期以后更改的文件。
               如果没有提供日期，只复制那些源时间
               比目标时间新的文件。
  /EXCLUDE:file1[+file2][+file3]...
               指定含有字符串的文件列表。每一个字符串
               必须在文件的单独行中。如果有任何
               字符串与要被复制的文件的绝对路径
               相符，那个文件将不会得到复制。
               例如，指定如 \obj\ 或 .obj 的字符串会排除
               目录 obj 下面的所有文件或带有
               .obj 扩展名的文件。
  /P           创建每个目标文件前提示。
  /S           复制目录和子目录，除了空的。
  /E           复制目录和子目录，包括空的。
               与 /S /E 相同。可以用来修改 /T。
  /V           验证每个新文件。
  /W           提示您在复制前按键。
  /C           即使有错误，也继续复制。
  /I           如果目标不存在，又在复制一个以上的文件，
               则假定目标一定是一个目录。
  /Q           复制时不显示文件名。
  /F           复制时显示完整的源和目标文件名。
  /L           显示要复制的文件。
  /G           允许将没有经过加密的文件复制到
               不支持加密的目标。
  /H           也复制隐藏和系统文件。
  /R           覆盖只读文件。
  /T           创建目录结构，但不复制文件。
               不包括空目录或子目录。/T /E 包括
               空目录和子目录。
  /U           只复制已经存在于目标中的文件。
  /K           复制属性。一般的 Xcopy 会重置只读属性。
  /N           用生成的短名复制。
  /O           复制文件所有权和 ACL 信息。
  /X           复制文件审核设置(隐含 /O)。
  /Y           复制文件审核设置(隐含 /O)。
               现存目标文件。
  /-Y          导致提示以确认改写一个
               现存目标文件。
  /Z            用重新启动模式复制网络文件。
命令行开关 /Y 可以预先在 COPYCMD 环境变量中设置。
这可能被命令行上的 /-Y 改写。

mapeimapei

如何正确使用COPY 和XCOPY命令?
　 ●将若干个文件联结成一个文件时，应使用COPY命令。
　 ●拷贝小于64KB的单个文件，使用COPY命令。拷贝大于64KB的文件，应使用XCOPY命令。
●拷贝多个文件应使用XCOPY命令。
　 ●拷贝子目录中的内容，应使用XCOPY／S命令。拷贝一批文件到软盘，应使用XCOPY/M命令。

HB天意

小马你能不能帮我写下？
反正你有我的pe。
我试了许多次了，都快绝望了。

421062724

晕，COPY不可能不行的

mapeimapei

天意，，你将WINPE.IS_隐藏了，怎么复制啊？？

如图：

wg0525

哦，不能隐藏是吧？
谢谢，我试试看。

HB天意

原帖由 mapeimapei 于 2008-9-19 11:32 发表
天意，，你将WINPE.IS_隐藏了，怎么复制啊？？

如图：
45948

问题找到了。
但是因为里面的部分配置文件不一样，所以还是启动不了。
小马能不能帮我把整个setup文件夹处理一下打包给我啊？

421062724

难怪说不能复制～COPY是不能复制隐藏文件的

liuyw001

呵呵，我之前遇到这个问题是这么解决的。

就你的代码来说，代码里有WINPEXP的地方，比如：
－－－－－－－－－－－－－－－
::设定PE安装文件夹的名称
Set PEDIR=%RP%\WINPEXP
－－－－－－－－－－－－－－－
把“WINPEXP”改成你要装在C盘的PE文件夹名称。比如：yidawpf
全部代码里的“WINPEXP”都要改成yidawpf。
然后再修改安装文件夹里的：MYINS.dll文件，改成MYINS.RAR。用WINRAR打开，把文件名是WINPEXP.BIN的改成yidawpf.bin。winpexpa.bin改为：yidawpfa.bin，winpexpg.bin改为：yidawpfg.bin。然后改回MYINS.DLL。
然后安装成功。
以上举一反三。
我对PE深层的东西不懂，只略通一点皮毛，奉行拿来主义，弄之前也不知道这么弄有没有不对，不过现在用着挺正常，就先用着了。

这是我的方法，不知道能不能帮到你。

[ 本帖最后由 liuyw001 于 2008-9-19 20:59 编辑 ]

HB天意

谢谢楼上的。
用小马的源码我已经搞定了。
不过现在还是有一点小问题。启动的时候中文变成乱码。
是那里出了问题呢？

421062724

少了个文件B开头的，在光盘根目录下的

mapeimapei

天意你将bootfont.bin，，WINNT.XPE，，WINPE.IS_都隐藏了，所以不行。。

之舞说了缺少bootfont.bin会乱码。。

你只要将ISO根目录下的自动播放的配置文件隐藏就好了（AUTORUN.APM和AUTORUN.INF），，其他的不要隐藏。。

[ 本帖最后由 mapeimapei 于 2008-9-19 22:27 编辑 ]