设为首页收藏本站
开启辅助访问 切换到宽版

无忧启动论坛

 找回密码
 注册
搜索
无忧启动论坛»论坛 › ::启动制作:: › 脚本讨论区 › 删除右键"新建"菜单中的多余项目[20080317]
系统gho:最纯净好用系统下载站投放广告、加入VIP会员，请联系 微信:wuyouceo
返回列表 发新帖
查看: 5667|回复: 5
打印 上一主题 下一主题

删除右键"新建"菜单中的多余项目[20080317]

[复制链接]
namejm
跳转到指定楼层
1#
发表于 2008-3-8 14:26:09 | 只看该作者 回帖奖励 |倒序浏览 |阅读模式
加入VIP会员，获无忧币，赠积分，送勋章，下载无限制，获论坛最高级会员权限 !
　　最近在测试软件，很多软件都喜欢在右键"新建"菜单下添加自己的专用文件格式选项，一圈测试下来，"新建"菜单里臃肿不堪，严重影响了右键的打开速度。
　　网上搜索能删除"新建"项目的软件，发现ShowNew不能删除 MS Office 系列的"新建"项目，并且不支持批量删除；ContextEdit 里转了半天，找不到删除的方法——并不是找不到删除选项，而是跑出来的项目太多，居然不提供搜索功能，想删除指定项目还得在成百上千个记录中寻找、定位，太不人性化了。
　　翻了一下以前写过的批处理，发现了一个好东西，于是，略做修改，发出来让大家用用。板砖之类的请尽管飞过来~~~

　　版本一：把注册表信息放到与批处理同目录的RegBackup文件夹下
  1. @echo off
  2. :: 　　一般情况下，右键"新建"菜单项目对应于注册表"HKEY_CLASSERS_ROORT\.后缀名"
  3. :: 项目下的"ShellNew"键。如果常规模式下删除不了，则把"HKEY_CLASSERS_ROORT\.后缀名"
  4. :: 删除掉即可(注意，可能会有后遗症)。
  5. ::    Code by namejm Modified on 2007.9.29～2008.3.17 CMD@XP

  7. mode con lines=25
  8. color 1f

  10. :Main
  11. cls
  12. title "新建"菜单项目删除器-删除模式
  13. echo.&echo.&echo.
  14. echo            本程序能删除右键菜单中"新建"项目下的多余内容，为"新建"菜单减肥！
  15. echo.
  16. echo            如果想让某种类型的文件不再出现在鼠标右键的"新建"菜单中，请直接
  17. echo.
  18. echo        输入该文件类型的后缀名。例如：rar。默认使用常规删除模式。
  19. echo.
  20. echo            如果常规删除不起作用，请使用强行删除模式，比如在对付 MS Office
  21. echo.
  22. echo        系列软件在"新建"菜单中的项目的时候。不过，此方式可能会产生后遗症。
  23. echo.
  24. echo            注意：需要点开"新建"菜单两次才能看到删除后的变化！
  25. echo.&echo.
  26. echo　　　　退出请选 0　　使用强行删除模式请在最前面添加 1　　恢复菜单项目请按 2
  27. echo.&echo.
  28. echo             　　请输入后缀名(多个后缀名用空格分开)：
  29. echo.
  30. set input=
  31. set /p input=             　　   
  32. if not defined input goto Main
  33. set "input=%input:"=%"
  34. if "%input%"=="0" exit
  35. set ShellNew=ShellNew
  36. if "%input:~0,1%"=="1" (
  37.     set ShellNew=
  38.     set "input=%input:~1%"
  39. )
  40. if "%input%"=="2" goto Repair
  41. md RegBackup 2>nul
  42. for %%i in (%input%) do (
  43.     reg export HKCR\.%%i\%ShellNew% RegBackup\_%%i.reg>nul 2>nul
  44.     if exist RegBackup\_%%i.reg (
  45.         more RegBackup\_%%i.reg>RegBackup\%%i.reg
  46.         echo ; 这是鼠标右键"新建"菜单项目 .%%i 类型的注册表信息，可作恢复之用>>RegBackup\%%i.reg
  47.         del /a /f RegBackup\_%%i.reg>nul 2>nul
  48.         reg delete HKCR\.%%i\%ShellNew% /f >nul 2>nul
  49.     )
  50. )
  51. rd RegBackup 2>nul
  52. goto Main

  54. :Repair
  55. cls
  56. title "新建"菜单项目删除器-恢复模式
  57. echo.&echo.&echo.
  58. echo            　　本模块只能恢复由本程序删除的右键"新建"菜单项目！
  59. echo.
  60. echo            　　如果想让某种类型的文件重新出现在鼠标右键的"新建"
  61. echo.
  62. echo        　　菜单中，请直接输入该文件类型的后缀名。例如：rar。
  63. echo.
  64. echo            　　注意：需要点开"新建"菜单两次才能看到恢复后的变化！
  65. echo.&echo.
  66. echo                 　　 退出请选 0　　返回删除界面请按 1
  67. echo.&echo.
  68. echo            　   　　请输入后缀名(多个后缀名用空格分开)：
  69. echo.
  70. set input=
  71. set /p input=      　　　      　　　　
  72. if not defined input goto Repair
  73. set "input=%input:"=%"
  74. if "%input%"=="0" exit
  75. if "%input%"=="1" goto Main
  76. if not exist RegBackup (
  77. 　　echo.&echo            　　没有可恢复的项目，恢复失败！按任意键返回...
  78.     pause>nul&goto Main
  79. )   
  80. for %%i in (%input%) do (
  81. 　　reg import RegBackup\%%i.reg>nul 2>nul||(
  82.         echo.&echo            　　    .%%i 类型恢复失败
  83.     )
  84. )
  85. echo.&set /p=            　　    按任意键返回...
  86. goto Repair
复制代码
　　版本二：把注册表信息写回注册表，不再保存在当前目录下
  1. @echo off
  2. :: 　　一般情况下，右键"新建"菜单项目对应于注册表"HKEY_CLASSERS_ROORT\.后缀名"
  3. :: 项目下的"ShellNew"键。如果常规模式下删除不了，则把"HKEY_CLASSERS_ROORT\.后缀名"
  4. :: 删除掉即可(注意，可能会有后遗症)。
  5. ::    Code by namejm Modified on 2007.9.29～2008.3.17 CMD@XP

  7. mode con lines=25
  8. color 1f

  10. :Main
  11. cls
  12. title "新建"菜单项目删除器-删除模式
  13. echo.&echo.&echo.
  14. echo            本程序能删除右键菜单中"新建"项目下的多余内容，为"新建"菜单减肥！
  15. echo.
  16. echo            如果想让某种类型的文件不再出现在鼠标右键的"新建"菜单中，请直接
  17. echo.
  18. echo        输入该文件类型的后缀名。例如：rar。默认使用常规删除模式。
  19. echo.
  20. echo            如果常规删除不起作用，请使用强行删除模式，比如在对付 MS Office
  21. echo.
  22. echo        系列软件在"新建"菜单中的项目的时候。不过，此方式可能会产生后遗症。
  23. echo.
  24. echo            注意：需要点开"新建"菜单两次才能看到删除后的变化！
  25. echo.&echo.
  26. echo　　　　退出请选 0　　使用强行删除模式请在最前面添加 1　　恢复菜单项目请按 2
  27. echo.&echo.
  28. echo             　　请输入后缀名(多个后缀名用空格分开)：
  29. echo.
  30. set input=
  31. set /p input=             　　   
  32. if not defined input goto Main
  33. set "input=%input:"=%"
  34. if "%input%"=="0" exit
  35. set ShellNew=ShellNew
  36. if "%input:~0,1%"=="1" (
  37.     set ShellNew=
  38.     set "input=%input:~1%"
  39. )
  40. if "%input%"=="2" goto Repair
  41. for %%i in (%input%) do (
  42.     reg copy HKCR\.%%i\%ShellNew% HKCR\-.%%i\%ShellNew% /f /s >nul 2>nul
  43.     reg delete HKCR\.%%i\%ShellNew% /f >nul 2>nul
  44. )
  45. echo.&set /p=            　　    按任意键返回...
  46. goto Main

  48. :Repair
  49. cls
  50. title "新建"菜单项目删除器-恢复模式
  51. echo.&echo.&echo.
  52. echo            　　本模块只能恢复由本程序删除的右键"新建"菜单项目！
  53. echo.
  54. echo            　　如果想让某种类型的文件重新出现在鼠标右键的"新建"
  55. echo.
  56. echo        　　菜单中，请直接输入该文件类型的后缀名。例如：rar。
  57. echo.
  58. echo            　　注意：需要点开"新建"菜单两次才能看到恢复后的变化！
  59. echo.&echo.
  60. echo                 　　 退出请选 0　　返回删除界面请按 1
  61. echo.&echo.
  62. echo            　   　　请输入后缀名(多个后缀名用空格分开)：
  63. echo.
  64. set input=
  65. set /p input=      　　　      　　　　
  66. if not defined input goto Repair
  67. set "input=%input:"=%"
  68. if "%input%"=="0" exit
  69. if "%input%"=="1" goto Main   
  70. for %%i in (%input%) do (
  71. 　　reg query HKCR\-.%%i\>nul 2>nul && (
  72.         reg copy HKCR\-.%%i HKCR\.%%i /f /s >nul 2>nul
  73.         reg delete HKCR\-.%%i /f>nul 2>nul
  74.     ) || (
  75.         echo.&echo            　　     没有可供恢复的 .%%i 类型注册表信息
  76.     )
  77. )
  78. echo.&set /p=            　　    按任意键返回...
  79. goto Repair
复制代码
　　更新历史：

2008.3.17 修正了一处错误，使得强制删除 MS Office 系列的新建项目不再出错；
2008.3.9 增添了一个新版本，新版本代码不再把注册表信息保存在当前目录下，而是写回注册表中；
2008.3.8 增添了恢复"新建"菜单中指定项目的功能，并精简了代码；
2007.11.17 发布初始版本

[ 本帖最后由 namejm 于 2008-3-16 11:29 PM 编辑 ]
回复

使用道具 举报

2#
发表于 2008-3-8 21:29:42 | 只看该作者
不错,有用..收下...
回复

使用道具 举报

fxyq
3#
发表于 2008-3-8 22:55:29 | 只看该作者
学习了，卷走……
谢谢！
回复

使用道具 举报

namejm
4#
 楼主| 发表于 2008-3-9 17:17:45 | 只看该作者
　　哦，是么？什么地方可以搞到呢？既然不是自带的，弄一个又何妨？批处理虽然不如专门的编程语言那么强悍，但是，杀鸡焉用宰牛刀？没必要为了一个功能就动辄开动体积以M计算的软件吧？
回复

使用道具 举报

awfiwgy
5#
发表于 2010-7-1 23:19:44 | 只看该作者
P处理真强大，学习了
回复

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|Archiver|捐助支持|无忧启动 ( 闽ICP备05002490号-1 )

闽公网安备 35020302032614号

GMT+8, 2024-11-17 07:37

Powered by Discuz! X3.3

© 2001-2017 Comsenz Inc.

快速回复 返回顶部 返回列表