帮我看看这个批处理

ljj850624

这个是我提取pooh ghostos.img 只是替换了名字  为什么 在u盘执行时 输入对应数字 说是 错误的 命令或者文件名呢
devload RAMFD.SYS
devload USBASPI.SYS /v /e /norst
devload ASPIDISK.SYS
tw /ns /np>nul
cls
echo off
echo  ====================== 一键恢复镜像到 C 盘 ========================
echo.
echo         在使用此功能前请确保U盘移动区根目录下有SYSTEM文件夹
echo       并且在SYSTEM文件夹下有GHOST.EXE及SYS1.GHO,SYS2.GHO..
echo   .SYS5.GHO中的任意一个(SYSTEM/*.GHO文件为任意镜像文件改成的镜像文件),
echo               请确认以上的文件夹及文件名均为大写
echo               硬盘中带有NTFS分区的推荐使用手动GHOST
echo.
echo       ========================================================
echo.
echo 　　        数字1－6对应U盘移动区SYSTEM目录下的GHO文件
echo.   
echo        　　          １、还原 SYS1.GHO  到C盘               
echo　　　　　　      ２、还原 SYS2.GHO  到C盘　　　　
echo         　　         ３、还原 SYS3.GHO  到C盘
echo         　　         ４、还原 SYS4.GHO  到C盘
echo        　　          ５、还原 SYS5.GHO  到C盘
echo.
echo            =============================================
echo            6、手动运行U盘移动区SYSTEM文件夹下的GHOST.EXE
echo       ========================================================
echo.
choice /c:123456 请选择要安装第几个镜像到C盘
if errorlevel 6 goto GHOST
if errorlevel 5 goto SYS5
if errorlevel 4 goto SYS4
if errorlevel 3 goto SYS3
if errorlevel 2 goto SYS2
if errorlevel 1 goto SYS1
:SYS1
for %%i in (z,y,x,w,v,u,t,s,r,q,p,o,n,m,l,k,j,i,h,g,f,e,d,c) do if exist %%i:\SYSTEM\ghost.exe %%i:\SYSTEM\ghost.exe -clone,mode=pload,src=%%i:\SYSTEM\SYS1.GHO:1,dst=1:1 -crcignore -sure -rb
ezboot.com
goto end
:SYS2
for %%i in (z,y,x,w,v,u,t,s,r,q,p,o,n,m,l,k,j,i,h,g,f,e,d,c) do if exist %%i:\SYSTEM\ghost.exe %%i:\SYSTEM\ghost.exe -clone,mode=pload,src=%%i:\SYSTEM\SYS2.GHO:1,dst=1:1 -crcignore -sure -rb
ezboot.com
goto end
:SYS3
for %%i in (z,y,x,w,v,u,t,s,r,q,p,o,n,m,l,k,j,i,h,g,f,e,d,c) do if exist %%i:\SYSTEM\ghost.exe %%i:\SYSTEM\ghost.exe -clone,mode=pload,src=%%i:\SYSTEM\SYS3.GHO:1,dst=1:1 -crcignore -sure -rb
ezboot.com
goto end
:SYS4
for %%i in (z,y,x,w,v,u,t,s,r,q,p,o,n,m,l,k,j,i,h,g,f,e,d,c) do if exist %%i:\SYSTEM\ghost.exe %%i:\SYSTEM\ghost.exe -clone,mode=pload,src=%%i:\SYSTEM\SYS4.GHO:1,dst=1:1 -crcignore -sure -rb
ezboot.com
goto end
:SYS5
for %%i in (z,y,x,w,v,u,t,s,r,q,p,o,n,m,l,k,j,i,h,g,f,e,d,c) do if exist %%i:\SYSTEM\ghost.exe %%i:\SYSTEM\ghost.exe -clone,mode=pload,src=%%i:\SYSTEM\SYS5.GHO:1,dst=1:1 -crcignore -sure -rb
ezboot.com
goto end
:GHOST
for %%i in (z,y,x,w,v,u,t,s,r,q,p,o,n,m,l,k,j,i,h,g,f,e,d,c) do if exist %%i:\SYSTEM\ghost.exe %%i:\SYSTEM\ghost.exe
GHOST.EXE
goto end
:end

x9tian

加上下面这句就行了

for %%i in (z,y,x,w,v,u,t,s,r,q,p,o,n,m,l,k,j,i,h,g,f,e,d) do if exist %%i:\SYSTEM\ghost.exe %%i:\SYSTEM\ghost.exe -clone,mode=pload,src=%%i:\SYSTEM\SYS%choice%.GHO:1,dst=1:1 -crcignore -sure -rb
ezboot.com

不才

嘿嘿，楼主确认系统中存在 ezboot.com 么？估计是它的问题。

lianjiang

1：1不会是u盘本身？

lianjiang

这个批处理用于u盘，似乎是有问题的。
通用性较差。

lianjiang

u盘启动的，首先应要完成是第一硬盘还是第二硬盘的判断。

ljj850624

谢谢各位老大，不才，说我3年发3贴 是我太菜了 最近才开始学习学习 启动方面的知识。我数半路出家啊 实在是不太好弄
那么 lianjiang 能给修改该下 带判断 第一第二硬盘的吗 我提取了飘雪的 自动搜寻ghost镜像安装的 但 看着有点有晕

ljj850624

原帖由 x9tian 于 2010-7-14 17:13 发表
加上下面这句就行了

for %%i in (z,y,x,w,v,u,t,s,r,q,p,o,n,m,l,k,j,i,h,g,f,e,d) do if exist %%i:\SYSTEM\ghost.exe %%i:\SYSTEM\ghost.exe -clone,mode=pload,src=%%i:\SYSTEM\SYS%choice%.GHO:1,dst=1: ...

都删掉了 那我按6的 功能就没有了吧

wang6610

原帖由 ljj850624 于 2010-7-14 22:48 发表


都删掉了 那我按6的 功能就没有了吧

那就从第二个IF开始删..............................

不才

嘿嘿，楼主不讲清楚，乡亲们就只能是连懵带猜的说了。
根据楼主所述：“执行时 输入对应数字 说是 错误的 命令或者文件名呢”，通常是在找不到驱动器上的“ghost.exe”或“sysx.gho”之后在指定的路径上找不到 ezboot.com 所致。从语句上讲，执行到“for %%i in (z,y,x,w,v,u,t,s,r,q,p,o,n,m,l,k,j,i,h,g,f,e,d,c) do if exist %%i:\SYSTEM\ghost.exe %%i:\SYSTEM\ghost.exe -clone,mode=pload,src=%%i:\SYSTEM\SYS1.GHO:1,dst=1:1 -crcignore -sure -rb”命令时即使找不到相应的文件，不会出现“错误的 命令或者文件名”提示，而只有当找不到ezboot.com 时，才有可能出现“错误的 命令或者文件名”提示。
至于整个批处理如何做更加合理，楼上的其他几位都是大家，只要楼主能说清楚具体要求（想达到的目的？运行环境？img加载方式？等等），或认真领会，不难得到答案。

ljj850624

我的要求很简单就是 希望量产u盘 后 执行 这个img 达到 从u盘里的gho文件 恢复系统到 c盘。因为我觉得这个 功能不错。附上 飘雪的 恢复img 里的AUTOEXEC.BAT
@echo off
IF NOT %CONFIG%==DOS LH SHSUCDX /D:?IDECD1 /D:?USBCD1 /D:?FWRCD1
IF NOT %CONFIG%==DOS FINDCD /S>NUL
IF "%CDROM%"=="" SET CDROM=0
TW /ns /np >nul
SMARTDRV.EXE
CTMOUSE.EXE

rem 如果选择驱动IDE/SATA/SCSI光驱，则认为从光盘启动，否则认为从U盘启动
set dstdisk=2
if %config%==CDROM set dstdisk=1

cls
echo.
echo.
echo.
echo 下面将搜索各盘GHO下的镜像和克隆工具，请按任意键……
echo.
echo （注意：如出现 Abort,Retry,Fail 出错提示，请按A键直接跳过）
echo.
pause >nul

set wxpdrv=
call findudrv gho\xp.gho
set wxpdrv=%udrv%

set wk3drv=
call findudrv gho\2k3.gho
set wk3drv=%udrv%

set ucddrv=
call findudrv gho\sys.gho
set ucddrv=%udrv%

set gstdrv=
call findudrv gho\ghost.exe
set gstdrv=%udrv%

set ucdinf=搜索结果：位于%ucddrv%
if #%ucddrv%==# set ucdinf=搜索结果：未找到
set wxpinf=搜索结果：位于%wxpdrv%
if #%wxpdrv%==# set wxpinf=搜索结果：未找到
set wk3inf=搜索结果：位于%wk3drv%
if #%wk3drv%==# set wk3inf=搜索结果：未找到
set gstinf=搜索结果：位于%gstdrv%
if #%gstdrv%==# set gstinf=搜索结果：未找到
set vcdinf=(找到光驱%cdrom%个，盘符为%cdrom1% %cdrom2% %cdrom3% )
if #%cdrom1%==# set vcdinf=(找到光驱%cdrom%个。           )

:menu
cls
echo            ┌─────────────────────┐
echo  ┌────┤       GHOST 方式恢复或安装系统菜单       ├─────┐
echo  │        └─────────────────────┘          │
echo  │1 - 手动运行SPFDISK分区                                         │
echo  │2 - 手动运行GHOST克隆 (不带任何参数运行)                        │
echo  │3 - 自动恢复备份系统 (第%dstdisk%硬盘第1分区的所有数据将丢失!)          │
echo  │4 - 克隆式安装WinXP SP3 VOL (第%dstdisk%硬盘第1分区的所有数据将丢失!)   │
echo  │5 - 克隆式安装Win2K3 SP2 VOL (第%dstdisk%硬盘第1分区的所有数据将丢失!)  │
echo  │6 - 退出到DOS                                                   │
echo  │7 - 重启                                                        │
echo  ├────────────────────────────────┤
echo  │注意：                                                          │
echo  │   A.如果从U盘启动，Ghost中U盘占据第一个盘，主机硬盘为第二个盘  │
echo  │   B.如克隆包位于U盘且分配了盘符，Ghost选文件时，请从盘符中选， │
echo  │     而不要从分区中去定位克隆包文件，否则克隆可能中断！         │
echo  │   C.克隆前必须在本机任何DOS下可读的盘的GHO目录中准备如下文件： │
echo  │    系统克隆镜像：        “SYS.GHO”        (%ucdinf%)         │
echo  │    WinXP安装镜像：        “XP.GHO”        (%wxpinf%)         │
echo  │    Win2K3安装镜像：        “2K3.GHO”        (%wk3inf%)         │
echo  │    系统克隆工具：        “GHOST.EXE”        (%gstinf%)         │
echo  ├────────────────────────────────┤
echo  │ %vcdinf%                 Email:pxdos@21cn.com│
echo  └────────────────────────────────┘
echo.
choice /C:1234567 "请输入你的选择:"
if errorlevel 7 goto 7
if errorlevel 6 goto 6
if errorlevel 5 goto 5
if errorlevel 4 goto 4
if errorlevel 3 goto 3
if errorlevel 2 goto 2
if errorlevel 1 goto 1

:1
spfdisk
goto menu

:2
if #%gstdrv%==# goto gsterr
%gstdrv%\gho\ghost.exe
goto menu

:3
if #%gstdrv%==# goto gsterr
if not #%ucddrv%==# goto autoghost
echo 错误：
echo     系统克隆镜像 sys.gho 未找到！
echo 击任意键回主选单……
pause >nul
goto menu

:4
if #%gstdrv%==# goto gsterr
if not #%wxpdrv%==# goto wxppart
echo 错误：
echo     系统克隆镜像 xp.gho 未找到！
echo 击任意键回主选单……
pause >nul
goto menu

:5
if #%gstdrv%==# goto gsterr
if not #%wk3drv%==# goto wk3part
echo 错误：
echo     系统克隆镜像 2k3.gho 未找到！
echo 击任意键回主选单……
pause >nul
goto menu

:6
cls
type a:help.txt
goto end

:7
r.com
goto end

:wxppart
echo.
echo 警告：        即将进行WinXP安装镜像恢复
echo     主机第%dstdisk%个硬盘第1分区上的所有数据将全部丢失，
echo     你可以按Ctrl-Alt-Del来中断本操作，否则按任意键继续……
pause >nul
%gstdrv%\gho\ghost.exe -clone,mode=pload,src=%wxpdrv%\gho\xp.gho:1,dst=%dstdisk%:1 -sure -rb
goto end

:wk3part
echo.
echo 警告：        即将进行Win2K3安装镜像恢复
echo     主机第%dstdisk%个硬盘第1分区上的所有数据将全部丢失，
echo     你可以按Ctrl-Alt-Del来中断本操作，否则按任意键继续……
pause >nul
%gstdrv%\gho\ghost.exe -clone,mode=pload,src=%wk3drv%\gho\2k3.gho:1,dst=%dstdisk%:1 -sure -rb
goto end

:autoghost
echo.
echo 警告：        即将进行已备份的系统镜像恢复
echo     主机第%dstdisk%个硬盘第1分区上的所有数据将全部丢失，
echo     你可以按Ctrl-Alt-Del来中断本操作，否则按任意键继续……
pause >nul
%gstdrv%\gho\ghost.exe -clone,mode=pload,src=%ucddrv%\gho\sys.gho:1,dst=%dstdisk%:1 -sure -rb
goto end

:gsterr
echo 错误：
echo     克隆工具Ghost.exe未找到，不能进行系统克隆操作！

:end

不才

嘿嘿，楼主的要求看似不高，但欲识别出被量产的u盘则要求不低。
但愿楼主能碰上一个有闲且有心情的好心人，能帮你满足这不高的要求。