求一个批处理机房ip通过mac 自动换 - 无忧启动论坛

@echo off
setlocal
:: 设置 IP 的映射
set "pc1_mac=XX-XX-XX-XX-XX-XX" :: 替换为 PC1 的实际 MAC 地址
set "pc1_ip=192.168.2.1"
set "pc2_mac=YY-YY-YY-YY-YY-YY" :: 替换为 PC2 的实际 MAC 地址
set "pc2_ip=192.168.2.2"
:: 获取当前计算机的 MAC 地址
for /f "tokens=2 delims=:" %%a in ('getmac /fo csv /nh') do (
set "current_mac=%%~a"
)
:: 去除 MAC 地址中的空格
set "current_mac=%current_mac: =%"
:: 从 IP 中提取最后一位作为计算机名
for /f "tokens=3 delims=." %%i in ("%pc1_ip%") do (
set "ip_suffix=%%i"
)
set "computer_name=pc%ip_suffix%"
:: 检查 MAC 地址并设置 IP 和计算机名
if /i "%current_mac%"=="%pc1_mac%" (
echo Setting IP to %pc1_ip% and Computer Name to %computer_name%
netsh interface ip set address "Ethernet" static %pc1_ip% 255.255.255.0
WMIC computersystem where name="%COMPUTERNAME%" call rename name="%computer_name%"
shutdown /r /t 0
) else if /i "%current_mac%"=="%pc2_mac%" (
echo Setting IP to %pc2_ip% and Computer Name to pc%ip_suffix%
netsh interface ip set address "Ethernet" static %pc2_ip% 255.255.255.0
for /f "tokens=3 delims=." %%i in ("%pc2_ip%") do (
set "ip_suffix=%%i"
)
set "computer_name=pc%ip_suffix%"
WMIC computersystem where name="%COMPUTERNAME%" call rename name="%computer_name%"
shutdown /r /t 0
) else (
echo No matching MAC address found. Exiting...
)
endlocal

复制代码

echo off
echo 正在配置IP地址，请稍候……
set "MASK=255.255.255.0"
set "GATEWAY=192.168.1.1"
set "DNS1=8.8.8.8"
set "DNS2=114.114.114.114"
set "WINS=192.168.1.1"
for /f "tokens=*" %%i in ('wmic Nic where "NetEnabled='true'" get MacAddress^,NetConnectionID /format:List^|find "="') do set "%%i"
for /f "delims=:" %%i in ('findstr /n /b /e ::::.*:::: "%~f0"') do (
for /f "tokens=1,2,4" %%i in ('more /e +%%i "%~f0" ^| find /i "%MacAddress::=-%"') do (
set "name=%%i" & set "IP=%%j" & set "Description=%%k"
)
)
if not defined name (
echo;没有匹配的MAC地址 & pause & exit /b
) else if not defined NetConnectionID (
echo;没找到已连接的网络 & pause & exit /b
)
reg add "HKLM\SYSTEM\ControlSet001\Services\lanmanserver\parameters" /v srvcomment /d "%Description%" /f >nul 2>nul
reg add "HKLM\SYSTEM\CurrentControlSet\Services\lanmanserver\parameters" /v srvcomment /d "%Description%" /f >nul 2>nul
reg add "HKLM\System\CurrentControlSet\Control\ComputerName\ComputerName" /v ComputerName /d "%name%" /f >nul 2>nul
reg add "HKLM\System\CurrentControlSet\Services\Tcpip\Parameters" /v "NV Hostname" /d "%name%" /f >nul 2>nul
reg add "HKLM\System\CurrentControlSet\Services\Tcpip\Parameters" /v Hostname /d "%name%" /f >nul 2>nul
netsh interface ip set address "%NetConnectionID%" static %IP% %Mask% %GATEWAY% 1 >nul 2>nul
netsh interface ip set dns "%NetConnectionID%" static %DNS1% register=PRIMARY >nul 2>nul
netsh interface ip add dns "%NetConnectionID%" %DNS2% index=2 >nul 2>nul
netsh interface ip set wins "%NetConnectionID%" static %WINS% >nul 2>nul
pause & exit /b
shutdown -r -t 3
del /q %0
:::: Your IP and MAC Addresses Here ::::
PC101 192.168.1.101 11-11-11-11-11-11 101号机
PC102 192.168.1.102 22-22-22-22-22-22 102号机
PC103 192.168.1.103 33-33-33-33-33-33 103号机

复制代码