WPS Office 2019(11.8.2.12265)精简绿色专业增强版 - 无忧启动论坛

@echo off
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\et.exe" /f /ve /t REG_SZ /d "%~dp0office6\wps.exe"
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\wpp.exe" /f /ve /t REG_SZ /d "%~dp0office6\wps.exe"
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\wps.exe" /f /ve /t REG_SZ /d "%~dp0office6\wps.exe"
::----------------写入注册信息，以取消首次启动时的对话框-------------------------------------------------------------------------------------------------
reg add "HKLM\SOFTWARE\WOW6432Node\Kingsoft\Office\6.0\Common" /f /v "hostprocname" /t REG_SZ /d "wpsoffice.exe"
Reg add "HKLM\SOFTWARE\WOW6432Node\Kingsoft\Office\6.0\Common" /f /v "do_not_detect_file_association_while_startup" /t REG_SZ /d "true"
::不自动切换皮肤
reg add "HKCU\SOFTWARE\Kingsoft\Office\6.0\Common" /f /v "autoSwitchSkin" /t REG_SZ /d "false"
::-------------------------安装路径------------------------------------------------------------------------------------------------------------------------
reg add "HKLM\SOFTWARE\WOW6432Node\Kingsoft\Office\6.0\Common" /f /v "InstallRoot" /t REG_SZ /d "%~dp0"
reg add "HKLM\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Kingsoft Office" /f /v "LocationRoot" /t REG_SZ /d "%~dp0"
reg add "HKCU\SOFTWARE\Classes\TypeLib\{7EA28F2F-D08B-4FE3-A88A-480640A2046B}\1.0\HELPDIR" /f /ve /t REG_SZ /d "%~dp0office6"
reg add "HKLM\SOFTWARE\Classes\TypeLib\{30E995E3-BD8B-42F1-8755-D6BEA44F9AD4}\1.0\HELPDIR" /f /ve /t REG_SZ /d "%~dp0office6"
::-------------------------oem信息，可自行更改---------------------------------------------------------------------------------------------------------------
Reg add "HKCU\SOFTWARE\Kingsoft\Office\6.0\common\UserInfo" /f /v "UserName" /t REG_SZ /d "wps"
Reg add "HKCU\SOFTWARE\Kingsoft\Office\6.0\common\UserInfo" /f /v "Company" /t REG_SZ /d "金山软件"
Reg add "HKCU\SOFTWARE\Kingsoft\Office\6.0\common\UserInfo" /f /v "Abbreviation" /t REG_SZ /d "Admin"
Reg add "HKCU\SOFTWARE\Kingsoft\Office\6.0\common\UserInfo" /f /v "LocateUserHaveSet" /t REG_DWORD /d "1"
::--------------------------创建快捷方式-----------------------------------------------------------------------------------------------------------------------
if not exist "%appdata%\Microsoft\Internet Explorer\Quick Launch\办公工具" md "%appdata%\Microsoft\Internet Explorer\Quick Launch\办公工具"
::模式设置
echo ::模式设置
echo ::prome_independ多组件模式-打开需要手动新建文件，无需要wpsoffice.exe文件支持
echo ::prome_fushion整合模式 -打开处于新建文件模式, 需要wpsoffice.exe文件支持
echo ::可使用下面命令打开设置
echo.
echo ksomisc.exe -showallinone
echo.
::窗口管理模式切换，默认使用多组件模式
::整合模式，打开处于新建文件模式, 需要wpsoffice.exe文件支持
reg add "HKLM\SOFTWARE\Wow6432Node\Kingsoft\Office\6.0\wpsoffice\Application Settings" /f /v "AppComponentMode" /t REG_SZ /d "prome_fushion"
::多组件模式-打开需要手动新建文件，无需要wpsoffice.exe文件支持
rem reg add "HKLM\SOFTWARE\WOW6432Node\Kingsoft\Office\6.0\wpsoffice\Application Settings" /f /v "AppComponentMode" /t REG_SZ /d "prome_independ"
mshta VBScript:Execute("Set a=CreateObject(""WScript.Shell""):Set b=a.CreateShortcut(""c:\Users\Public\Desktop\WPS Office.lnk""):b.TargetPath=""%~dp0office6\ksolaunch.exe"":b.Arguments="" /prometheus /fromksolaunch /from=desktop_shortcut"":b.WorkingDirectory=""%~dp0office6"":b.Description=""一站式办公平台"":b.Save:close")
mshta VBScript:Execute("Set a=CreateObject(""WScript.Shell""):Set b=a.CreateShortcut(""%appdata%\Microsoft\Internet Explorer\Quick Launch\办公工具\WPS Office.lnk""):b.TargetPath=""%~dp0office6\ksolaunch.exe"":b.Arguments="" /prometheus /fromksolaunch /from=desktop_shortcut"":b.WorkingDirectory=""%~dp0office6"":b.Description=""一站式办公平台"":b.Save:close")
::---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
::---文件-选项=自定义功能区-安全---复选框选择打开或关闭---------------------------------------------------
if exist office6\setup\Kingsoft xcopy /s /q /y /r office6\setup\Kingsoft "%appdata%\Kingsoft"
::-------------------------激活信息--------------------------------------------------------------------
xcopy /s /q /y /r office6\setup\ProgramData "%ProgramData%"
::-------------------------注册公式编辑器字体------------------------------------------------------------
xcopy /y /r "%ProgramData%\Kingsoft\office6\mtfont\mtextra.ttf" "%windir%\fonts"
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts" /f /v "MT Extra (TrueType)" /t REG_SZ /d "mtextra.ttf"
::公式编辑器自动初始化
start "" "%~dp0office6\mui\zh_CN\resource\ksee\EqnEdit.exe"
::-----------------------检查是否具备宏开发环境---------------------------------
if not exist "C:\Program Files (x86)\Common Files\Microsoft Shared\Office10\MSO.DLL" xcopy /s /q /y /r Office10 "C:\Program Files (x86)\Common Files\Microsoft Shared\Office10" 2>nul
if not exist "C:\Program Files (x86)\Common Files\Microsoft Shared\Office10\MSO.DLL" (
echo.
echo.
echo 未检测到 ms office 共享组件 MSO.DLL ！！！
echo.
echo.
pause
goto vbend
)
::检查是否安装vba环境
for /f %%a in ('reg query "HKLM\SOFTWARE\WOW6432Node\Microsoft\VBA"^|findstr /i /l "Vbe6DllPath"') do set wv=%%a
if "%wv%" == "Vbe6DllPath" goto vbend
for /f %%a in ('reg query "HKLM\SOFTWARE\WOW6432Node\Microsoft\VBA"^|findstr /i /l "Vbe71DllPath"') do set wv=%%a
if "%wv%" == "Vbe71DllPath" (
for /f "tokens=3" %%a in ('reg query "HKLM\SOFTWARE\WOW6432Node\Microsoft\VBA" /v "Vbe71DllPath"') do reg add "HKLM\SOFTWARE\WOW6432Node\Microsoft\VBA" /f /v "Vbe6DllPath" /t REG_SZ /d "%%a"
goto vbend
)
echo.
echo.
echo 系统未安装vba，wps开发工具不能启用宏，请检查！！！
echo.
echo.
pause
:vbend
::-------------------ksomisc.exe配置文件---------------------------------
if not exist utility md utility
if not exist utility\install.ini (
>>utility\install.ini echo [installinfo]
>>utility\install.ini echo common=1
>>utility\install.ini echo wps=1
>>utility\install.ini echo wpp=1
>>utility\install.ini echo et=1
>>utility\install.ini echo template=1
>>utility\install.ini echo assoword=0
>>utility\install.ini echo assoexcel=0
>>utility\install.ini echo assopowerpnt=0
>>utility\install.ini echo savetomso=1
>>utility\install.ini echo desktopshortcuts=1
>>utility\install.ini echo startmenudir=WPS Office 专业增强版
>>utility\install.ini echo theme=0
>>utility\install.ini echo vba=1
>>utility\install.ini echo compatiblemso=1
>>utility\install.ini echo assopdf=0
>>utility\install.ini echo assopic=0
>>utility\install.ini echo assopic2=0
>>utility\install.ini echo [version]
>>utility\install.ini echo display=WPSPlus
>>utility\install.ini echo [modulestate]
>>utility\install.ini echo wps=1
>>utility\install.ini echo wpp=1
>>utility\install.ini echo et=1
>>utility\install.ini echo pdf=0
>>utility\install.ini echo [localInfo]
>>utility\install.ini echo uselocal=156
>>utility\install.ini echo instlanguage=2052
>>utility\install.ini echo [diffPatch]
>>utility\install.ini echo down=1
>>utility\install.ini echo [setupexepath]
>>utility\install.ini echo pathname=
>>utility\install.ini echo [update]
>>utility\install.ini echo redirect=1
>>utility\install.ini echo URLSelectType=7
>>utility\install.ini echo [languagePack]
>>utility\install.ini echo zh_CN=1
)
cls
echo.
echo.
echo 如需改变默认文档关联，请使用ksomisc配置工具进行设置
echo.
echo 高级→兼容设置→勾选√wps office 兼容第三方系统和软件
echo.
echo.
pause
start "" "%~dp0office6\ksomisc.exe"

复制代码