无忧启动论坛

标题: BC3配置文件 [打印本页]

作者: liuhj 时间: 2009-1-5 14:06
标题: BC3配置文件
Beyond Compare 3是一款不错的文件、文件夹比较工具。有人说不能注册右键，因此作了一个配置文件，希望对大家有用。将BC3.CMD放到程序文件夹中运行即可。

BC3.CMD
——————————————————————————————
@ECHO OFF

REM 将当前路径设为变量
SET BC3PATH=%~DP0

REM 创建用户配置文件，关闭初次启动程序时的设置向导
IF NOT EXIST "%USERPROFILE%\Application Data\Scooter Software\Beyond Compare 3" MD "%USERPROFILE%\Application Data\Scooter Software\Beyond Compare 3"
COPY /Y NUL "%USERPROFILE%\Application Data\Scooter Software\Beyond Compare 3\BCState.xml"
(
ECHO ^<?xml version="1.0" encoding="UTF-8"?^>
ECHO ^<!-- Produced by Beyond Compare 3 from Scooter Software --^>
ECHO ^<BCState^>
ECHO    ^<TBcState^>
ECHO       ^<FirstStartup Value="False"/^>
ECHO       ^<FormPosStr Value="110;111;980;737"/^>
ECHO    ^</TBcState^>
ECHO ^</BCState^>
) >> "%USERPROFILE%\Application Data\Scooter Software\Beyond Compare 3\BCState.xml"

REM 注册右键
REG ADD "HKCR\*\shellex\ContextMenuHandlers\CirrusShellEx" /ve /t REG_SZ /d "{57FA2D12-D22D-490A-805A-5CB48E84F12A}" /f
REG ADD "HKCR\CLSID\{57FA2D12-D22D-490A-805A-5CB48E84F12A}" /ve /t REG_SZ /d "CirrusShellEx" /f
REG ADD "HKCR\CLSID\{57FA2D12-D22D-490A-805A-5CB48E84F12A}\InProcServer32" /ve /t REG_SZ /d "%BC3PATH%BCShellEx.dll" /f
REG ADD "HKCR\CLSID\{57FA2D12-D22D-490A-805A-5CB48E84F12A}\InProcServer32" /v "ThreadingModel" /t REG_SZ /d "Apartment" /f
REG ADD "HKCR\Directory\shellex\ContextMenuHandlers\CirrusShellEx" /ve /t REG_SZ /d "{57FA2D12-D22D-490A-805A-5CB48E84F12A}" /f
REG ADD "HKCR\Folder\shellex\ContextMenuHandlers\CirrusShellEx" /ve /t REG_SZ /d "{57FA2D12-D22D-490A-805A-5CB48E84F12A}" /f
REG ADD "HKCR\lnkfile\shellex\ContextMenuHandlers\CirrusShellEx" /ve /t REG_SZ /d "{57FA2D12-D22D-490A-805A-5CB48E84F12A}" /f

REM 程序基本设置
REG ADD "HKCU\Software\Scooter Software\Beyond Compare 3" /v "SupportsMerge" /t REG_DWORD /d 0x1 /f
REG ADD "HKCU\Software\Scooter Software\Beyond Compare 3\BcShellEx" /v "Viewers" /t REG_SZ /d "Text Compare;Data Compare;Hex Compare;MP3 Compare;Picture Compare;Version Compare" /f
REG ADD "HKCU\Software\Scooter Software\Beyond Compare 3\BcShellEx" /v "ArchiveMasks" /t REG_SZ /d "*.7z;*.7z.001;*.bcpkg;*.bcs;*.bcss;*.cab;*.chm;*.ear;*.gz;*.jar;*.rar;*.tar;*.tar.gz;*.tgz;*.war;*.zip;" /f

REM 注册右键
REG ADD "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Shell Extensions\Approved" /v "{57FA2D12-D22D-490A-805A-5CB48E84F12A}" /t REG_SZ /d "Beyond Compare 3 Shell Extension" /f

GOTO :EOF
——————————————————————————————

注：汉化版下载：http://www.greendown.cn/soft/2507.html

作者: lwz 时间: 2009-1-5 17:42
经常用BC2，很好用的
BC3应该更强大了，下载了看看

作者: CWD 时间: 2009-1-5 18:15
是我说的不能注册右键菜单，看来兄弟解决了一个问题啊，共享之啦，等下测试。。。
另：是否遇到打开比较文件夹中位置时提示错误问题？

作者: 0cat0 时间: 2009-1-5 19:35
已经好久不用BC了，ExamDiff Pro更强大的说

作者: liuhj 时间: 2009-1-5 23:23
3楼CWD ：
没有遇到打开比较文件夹位置时提示错误的问题。

4楼0cat0：
可能各人看法不同吧。
比较文件ExamDiff Pro不区分编码，但BC3是区分编码的。
比较文件夹时，ExamDiff Pro不是在原位置展开子目录，而是打开一个新窗口比对子目录，个人觉着不方便。而BC3是在原位置展开子目录，一目了然。

作者: nihao6227 时间: 2009-1-6 15:47
BC3遇到相同大小的不同文件的时候就感冒了，，，

作者: CWD 时间: 2009-1-6 21:39

原帖由 nihao6227 于 2009-1-6 15:47 发表
BC3遇到相同大小的不同文件的时候就感冒了，，，

呵呵。。。好好用吧，把BC3的比较方式功能用好咯，不会那么容易感冒滴。。。

作者: zannet 时间: 2009-1-6 23:29
其实在C:\Documents and Settings\用户名\Application Data\Scooter Software\Beyond Compare 3的几份XML文件就是配置文件.设置好后把它们放到Beyond Compare 3的目录就可以!

作者: CWD 时间: 2009-1-8 23:35
你们真的没有碰到此问题？！

进入文件夹对比界面后，点打开快捷按钮出现此提示！

作者: CWD 时间: 2009-1-10 14:18

原帖由 CWD 于 2009-1-8 23:35 发表
你们真的没有碰到此问题？！

52627

进入文件夹对比界面后，点打开快捷按钮出现此提示！

没人注意到此问题么？还是都跟我一样没在PE下用过这个BC3。。。

作者: 135956 时间: 2010-1-18 12:01
早前遇到个问题，就是安装版能右键关联，绿色版的没却没有那个注册右键的选项出来。
　搞到不能用绿色的版本。

作者: feilang999 时间: 2010-4-19 02:59
LZ大大，偶想知道怎么样可以反注册呢？就是在右键菜单里去掉比较~~

欢迎光临无忧启动论坛 (http://wuyou.net./)