无忧启动论坛

标题: NTFS文件锁定程序 V1.0 [打印本页]

作者: dudubird 时间: 2008-10-24 14:12
标题: NTFS文件锁定程序 V1.0
软件名称： NTFS文件锁定程序 V1.0
软件大小：222KB
软件语言：简体中文
软件类别：国产软件 / 免费版 / 文档管理
运行环境：NT/2000/XP/2003/
软件主页:http://bigtoothcat.2008red.com/
软件更新：2008-10-24 10:07:13
MD5校验码： c2f55cef98e3b914146adc5d20ca119f

软件介绍：

本程序可以锁定NTFS分区的文件或文件夹，使其具有防删，禁读，禁改名，隐藏等属性，
当锁定禁读时还可以防止别人复制；锁定过程只是修改了NTFS文件的访问权限,因此它不会改
写注册表，不创建隐藏文件夹，不改变文件结构，完全不会损坏原有数据。如果提示有木马纯
属误报，这个跟打包程序加壳有关。如需下载 For WinPE 版本请访问软件主页。

下载地址：http://www.namipan.com/d/a046cc2 ... 7cf20cfc990ce030200

[ 本帖最后由 dudubird 于 2008-10-24 14:50 编辑 ]

预览.JPG (37.81 KB, 下载次数: 92)

预览2.JPG (27.31 KB, 下载次数: 87)

预览3.jpg (22.22 KB, 下载次数: 86)

NTFS文件锁定程序 V1.0.rar

128.95 KB, 下载次数: 212, 下载积分: 无忧币 -2

作者: haiou327 时间: 2008-10-24 15:49
@ECHO OFF
REM CACLS只是锁定文件的属性，所以要防删就先要设置只读属性，隐藏也一样；不过完全锁定则不用预先设置属性；
REM 另外，要解除文件的所有属性也必须先用CACLS对文件解锁。
SET TT=NTFS文件锁定程序 V1.0——大牙猫电脑维护站 http://bigtoothcat.2008red.com/
SET SM1= 请输入文件或文件夹的名称(包含路径和扩展名)，然后按Enter键；与本程序路径相同的可以不输路径或按Tab键快速切换；也可以把文件或文件夹直接拖到本窗口。
SET NOTICE= 注意：文件的扩展名可在辅助工具中显示；文件名或路径有空格的请用双引号 " 括起来，如"D:\大牙猫\system 1.gho"
SET SM2=返回请输0。
SET CG=成功，请用右键菜单刷新文件夹。
COLOR 1E
TITLE %TT%

:BEGIN
SET LOOP=
CLS
ECHO.
ECHO 　　　       　　　 ┏━━━━━━━━━━━━┓
ECHO 　　　       ┏━━━━┫  NTFS文件锁定程序 V1.0 ┣━━━━┓
ECHO 　　　       ┃　　 ┗━━━━━━━━━━━━┛       ┃
ECHO             ┃                                           ┃
ECHO             ┃  [1] 初级锁定（防删，只读，可改名，非隐藏）┃
ECHO             ┃                                           ┃
ECHO 　　          ┃  [2] 中级锁定（防删，只读，可改名，隐藏）  ┃
ECHO 　　　       ┃　                                        ┃
ECHO 　　          ┃  [3] 高级锁定（防删，禁读，禁改名，非隐藏）┃
ECHO 　　　       ┃                                           ┃
ECHO 　　　       ┃  [4] 完全锁定（防删，禁读，禁改名，隐藏）  ┃
ECHO             ┃                                           ┃
ECHO             ┃  [5] 解锁（解除所有属性）             ┃
ECHO             ┃                                           ┃
ECHO             ┃  [6] 辅助工具    [7] 帮助    [0] 退出 ┃
ECHO             ┃                                           ┃
ECHO 　　　       ┣━━━━━━━━━━━━━━━━━━━━━━┫
ECHO 　　　       ┃    注：只对NTFS格式分区的文件有效。    ┃
ECHO 　　          ┗━━━━━━━━━━━━━━━━━━━━━━┛
ECHO.
SET Choice=
SET /P Choice=　　　　       请按数字选择您要进行的操作，然后按Enter键：

IF NOT '%Choice%'=='' SET Choice=%Choice:~0,1%
IF /I '%Choice%'=='1' GOTO CJSD
IF /I '%Choice%'=='2' GOTO ZJSD
IF /I '%Choice%'=='3' GOTO GJSD
IF /I '%Choice%'=='4' GOTO WQSD
IF /I '%Choice%'=='5' GOTO JS
IF /I '%Choice%'=='6' GOTO FZGJ
IF /I '%Choice%'=='7' GOTO HELP
IF /I '%Choice%'=='0' GOTO EXIT
GOTO BEGIN

:CJSD
SET LOOP=CJSD
CLS
ECHO.
ECHO                   初级锁定（防删，只读，可改名，非隐藏）
ECHO.
ECHO %SM1%
ECHO.
ECHO %NOTICE%
ECHO.
ECHO %SM2%
ECHO.
SET Choice=
SET /P Choice=需要锁定的文件或文件夹是：
IF '%Choice%'=='0' GOTO BEGIN
IF '%Choice%'=='' GOTO CJSD
IF NOT EXIST %Choice% GOTO NOFILE
ECHO.
echo y| cacls %Choice% /p everyone:f >nul
attrib +r -h +s %Choice%
echo y| cacls %Choice% /p everyone:r >nul
ECHO 恭喜! %Choice%已锁定。
ECHO.
PAUSE
GOTO CJSD

:ZJSD
SET LOOP=ZJSD
CLS
ECHO.
ECHO                      中级锁定（防删，只读，可改名，隐藏）
ECHO.
ECHO %SM1%
ECHO.
ECHO %NOTICE%
ECHO.
ECHO %SM2%
ECHO.
SET Choice=
SET /P Choice=需要锁定的文件或文件夹是：
IF '%Choice%'=='0' GOTO BEGIN
IF '%Choice%'=='' GOTO ZJSD
IF NOT EXIST %Choice% GOTO NOFILE
ECHO.
echo y| cacls %Choice% /p everyone:f >nul
attrib %Choice% +r +h +s
echo y| cacls %Choice% /p everyone:r >nul
ECHO 恭喜! %Choice%已锁定。
ECHO.
PAUSE
GOTO ZJSD

:GJSD
SET LOOP=GJSD
CLS
ECHO.
ECHO                   高级锁定（防删，禁读，禁改名，非隐藏）
ECHO.
ECHO %SM1%
ECHO.
ECHO %NOTICE%
ECHO.
ECHO %SM2%
ECHO.
SET Choice=
SET /P Choice=需要锁定的文件或文件夹是：
IF '%Choice%'=='0' GOTO BEGIN
IF '%Choice%'=='' GOTO GJSD
IF NOT EXIST %Choice% GOTO NOFILE
ECHO.
echo y| cacls %Choice% /p everyone:f >nul
attrib %Choice% +r -h +s
echo y| cacls %Choice% /D everyone >nul
ECHO 恭喜! %Choice%已锁定。
ECHO.
PAUSE
GOTO GJSD

:WQSD
SET LOOP=WQSD
CLS
ECHO.
ECHO                      完全锁定（防删，禁读，禁改名，隐藏）
ECHO.
ECHO %SM1%
ECHO.
ECHO %NOTICE%
ECHO.
ECHO %SM2%
ECHO.
SET Choice=
SET /P Choice=需要锁定的文件或文件夹是：
IF '%Choice%'=='0' GOTO BEGIN
IF '%Choice%'=='' GOTO WQSD
IF NOT EXIST %Choice% GOTO NOFILE
ECHO.
echo y| cacls %Choice% /p everyone:f >nul
attrib %Choice% +r +h +s
echo y| cacls %Choice% /D everyone >nul
ECHO 恭喜! %Choice%已锁定。
ECHO.
PAUSE
GOTO WQSD

:JS
SET LOOP=JS
CLS
ECHO.
ECHO                            解锁（解除所有属性）
ECHO.
ECHO %SM1%
ECHO.
ECHO %NOTICE%
ECHO.
ECHO %SM2%
ECHO.
SET Choice=
SET /P Choice=需要解锁的文件或文件夹是：
IF '%Choice%'=='0' GOTO BEGIN
IF '%Choice%'=='' GOTO JS
IF NOT EXIST %Choice% GOTO NOFILE
echo y| cacls %Choice% /p everyone:f >nul
attrib %Choice% -r -h -s
ECHO.
ECHO 恭喜! %Choice%已解锁。
ECHO.
PAUSE
GOTO JS

:NOFILE
ECHO.
ECHO 输入的文件不存在! 请确定输入是否正确。
ECHO.
ECHO 按任意键重新输入...
PAUSE >NUL
GOTO %LOOP%

:FZGJ
CLS
ECHO.
ECHO 　　　       　　　 ┏━━━━━━━━━━━━┓
ECHO 　　　       ┏━━━━┫       辅助工具       ┣━━━━┓
ECHO 　　　       ┃　　 ┗━━━━━━━━━━━━┛       ┃
ECHO             ┃                                           ┃
ECHO             ┃          [1] 显示隐藏文件             ┃
ECHO             ┃                                           ┃
ECHO 　　          ┃          [2] 不显示隐藏文件             ┃
ECHO 　　　       ┃　                                        ┃
ECHO 　　          ┃          [3] 显示文件扩展名             ┃
ECHO 　　　       ┃                                           ┃
ECHO 　　　       ┃          [4] 不显示文件扩展名          ┃
ECHO             ┃                                           ┃
ECHO             ┃          [5] 查看分区格式             ┃
ECHO             ┃                                           ┃
ECHO             ┃          [0] 返回上级菜单             ┃
ECHO 　　　       ┃                                           ┃
ECHO 　　          ┗━━━━━━━━━━━━━━━━━━━━━━┛
ECHO.
SET Choice=
SET /P Choice=　　　　       请按数字选择您要进行的操作，然后按Enter键：

IF NOT '%Choice%'=='' SET Choice=%Choice:~0,1%
IF /I '%Choice%'=='1' GOTO XSYC
IF /I '%Choice%'=='2' GOTO BXSYC
IF /I '%Choice%'=='3' GOTO XSKZM
IF /I '%Choice%'=='4' GOTO BXSKZM
IF /I '%Choice%'=='5' GOTO CKFQ
IF /I '%Choice%'=='0' GOTO BEGIN
GOTO FZGJ

:XSYC
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t reg_dword /d 1 /f >NUL
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v HideFileExt /t reg_dword /d 0 /f >NUL
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t reg_dword /d 1 /f >NUL
ECHO.
ECHO 显示隐藏文件%CG%
ECHO.
PAUSE
GOTO FZGJ

:BXSYC
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t reg_dword /d 00000000 /f >NUL
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v HideFileExt /t reg_dword /d 00000001 /f >NUL
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t reg_dword /d 00000000 /f >NUL
ECHO.
ECHO 不显示隐藏文件%CG%
ECHO.
PAUSE
GOTO FZGJ

:XSKZM
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v HideFileExt /t reg_dword /d 00000000 /f >NUL
ECHO.
ECHO 显示文件扩展名%CG%
ECHO.
PAUSE
GOTO FZGJ

:BXSKZM
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v HideFileExt /t reg_dword /d 00000001 /f >NUL
ECHO.
ECHO 不显示文件扩展名%CG%
ECHO.
PAUSE
GOTO FZGJ

:CKFQ
ECHO.
set/p pan=请输入要查看的盘符（不带冒号）：
for /f "tokens=1,2" %%i in ('chkntfs %pan%:') do (
set var=%%j
goto type
)
goto :eof
:type
set var=%var:。=%
ECHO.
echo %pan%盘的文件系统类型是 %var%
ECHO.
pause
set pan=
goto FZGJ

:HELP
CLS
ECHO.
ECHO    本程序可以锁定文件或文件夹，当需要改变锁定方式时直接选用其他锁定方式就行了，
ECHO 不用事先解锁，当锁定禁读时还可以防止别人复制；锁定过程只是修改了NTFS文件的访问权
ECHO 限,因此它不会改写注册表，不创建隐藏文件夹，不改变文件结构，完全不会损坏原有数据,
ECHO 而且这个过程是不需要输入密码的，除非您给本程序加入启动密码，否则任何使用本程序的
ECHO 人都可以解锁文件。另外，锁定只是相对Windows环境而言，在DOS环境却是可以访问和删除
ECHO 锁定文件的，隐藏也只是改变文件的隐藏属性，所以要实现绝对的锁定和隐藏请使用其他软
ECHO 件，本程序只适合忽悠小朋友。
ECHO.
ECHO    本程序免费使用，禁止利用本软件资源进行任何商业盈利活动，否则产生的一切后果将
ECHO 由您自己承担!
ECHO.
ECHO 如需For WinPE版本请访问软件主页:http://bigtoothcat.2008red.com/
ECHO.
ECHO 版权所有 (c)2008，Bigtoothcat 保留所有权利                2008年10月24日
ECHO.
ECHO 请按任意键返回...
PAUSE >NUL
GOTO BEGIN

:EXIT
SET TT=
SET SM1=
SET SM2=
SET Choice=
SET LOOP=
SET CG=
CLS
ECHO.
ECHO 本程序由Bigtoothcat设计，更多精彩内容请访问大牙猫电脑维护站。
ECHO.
ECHO http://bigtoothcat.2008red.com/
ECHO.
ECHO 请按任意键退出...
PAUSE >NUL

作者: haiou327 时间: 2008-10-24 15:51
右键安全就可以解除.

[ 本帖最后由 haiou327 于 2008-10-24 15:55 编辑 ]

wuyou.JPG (28.42 KB, 下载次数: 82)

作者: lxl1638 时间: 2008-10-24 17:14
"防删，禁读，禁改名"没有意义，这样的文件或目录谁也用不了，包括你自己。
建议加上一项"防删，只读，禁改名，禁修改"，本人系统的几十个重要文件(包括注册表)就是这样设置的，上网裸奔。

作者: dudubird 时间: 2008-10-24 17:24
还是大元帅厉害，偶是班门弄斧了，得向您好好学习！

作者: dudubird 时间: 2008-10-26 11:36
标题: 不得不请教老九！
我试着设置你说的“防删，只读，禁改名，禁修改”，但始终研究不出来，能不能指点一下，最好能给出批处理代码，还有那个锁注册表的最实用了，能不能也说一下方法，谢谢！

作者: lxl1638 时间: 2008-10-26 13:19

原帖由 dudubird 于 2008-10-26 11:36 发表
我试着设置你说的“防删，只读，禁改名，禁修改”，但始终研究不出来，能不能指点一下，最好能给出批处理代码，还有那个锁注册表的最实用了，能不能也说一下方法，谢谢！

不懂屁处理，本人是选定一堆文件后，用这个搞的

作者: dudubird 时间: 2008-10-26 16:48
标题: 明白了！
经过研究，被限制为“防删，只读，禁改名，禁修改”的文件夹还是可以修改名称的，只是这个文件夹里面的文件不能修改名称，也就是说“禁改名”是对所设置文件夹里面的文件而言。其实这个功能在程序的”初级锁定“就已经实现，只不过注明的”可改名“是对所设置的一级文件夹夹而言。不过，老九不说我还不懂被锁定文件夹里面的文件是禁改名的，而且还发现锁定文件夹后也不能在此文件夹里面创建文件，从防毒角度来看，似乎还有点用处，看来要在帮助信息里面再说明一下才行。

[ 本帖最后由 dudubird 于 2008-10-26 16:54 编辑 ]

作者: haiou327 时间: 2008-10-26 20:01
老九有没有办法限制父目录不能改名,只读. 非子目录

禁读防改名没有什么意义.把自己也堵在门外了.

[ 本帖最后由 haiou327 于 2008-10-26 20:04 编辑 ]

作者: haiou327 时间: 2008-10-26 20:03

防删，只读，禁改名，禁修改

复制代码

作者: lxl1638 时间: 2008-10-27 00:18

原帖由 dudubird 于 2008-10-26 16:48 发表
经过研究，被限制为“防删，只读，禁改名，禁修改”的文件夹还是可以修改名称的，只是这个文件夹里面的文件不能修改名称，也就是说“禁改名”是对所设置文件夹里面的文件而言。其实这个功能在程序的”初级锁定“ ...

.......................................................................................

未命名0.PNG (11.29 KB, 下载次数: 80)

未命名1.PNG (10.36 KB, 下载次数: 75)

未命名2.PNG (10.03 KB, 下载次数: 79)

未命名3.PNG (10.18 KB, 下载次数: 82)

作者: haiou327 时间: 2008-10-27 12:16
老九这个是设置了WINDOWS目录安全属性,所以17pholemes1001186.exe只读不可修改,但17pholemes1001186.exe的上一级目录还是可以改名的.(只是WINDOWS这个目录比较特殊不能改名)
有没有方法直接对17pholemes1001186.exe安全设置达到目的为只读不可改名.不用设置17pholemes1001186.exe上一级目录

[ 本帖最后由 haiou327 于 2008-10-27 12:40 编辑 ]

作者: dudubird 时间: 2008-10-27 14:24
是啊，不知道老九是把权限设置在Windows文件夹还是直接设置在17pholemes1001186.exe，Windows文件夹是系统文件夹，本身就限制改名的。如果是直接对17pholemes1001186.exe设置即可限制其改名，那具体应该勾哪些选项呢？能否贴出所打√的选项，好让大家研究研究。

作者: zqjiang 时间: 2008-10-27 16:24
最有用的就是
防删，只读，禁改名，禁修改
楼主可以实现吗

作者: dudubird 时间: 2008-11-23 14:46
标题: 即将推出NTFS文件锁定程序V1.2
目前已发现《NTFS文件锁定程序V1.1》至少存在以下两个bug

1、当文件夹中有文件时，无法锁定该文件夹。

2、当锁定驱动器时，无法解锁。

这两个问题都已经找到解决办法，等再进一步测试后就发布，敬请关注大牙猫电脑维护站！

初步设想：增加一个比较实用的功能就是锁定注册表不让任何人修改，包括VIRUS也不能修改，这样就可以不用杀毒软件就可以上网裸奔了，中了VIRUS只要重启系统就OK了，因为VIRUS无法修改注册表。不过需要等待进一步测试！

作者: zhh9150 时间: 2008-11-27 10:24
NTFS文件加密后，没有备份数字证书，现在打不开了，咋办？

作者: hapy08 时间: 2008-11-27 22:00
偶也喜欢裸奔，期待LZ的大作

作者: woshiwo99 时间: 2008-11-27 22:32
这个我得研究研究啊。

作者: biiq 时间: 2008-12-6 18:42
学习了。顶
...

欢迎光临无忧启动论坛 (http://wuyou.net./)